QUOTE (sb93 @ 29.06.2022, 14:14 Uhr)
Hallo liebe Heidenhainexperten,
ich komme seit kurzem auch in den Genuss an einer TNC 620 im 3-Achs Bereich zu arbeiten. Ich habe noch nicht viel Erfahrung und arbeite gerade meine alten Lehrgangsunterlagen von 2014 durch um ein bisschen Verständnis zu gewinnen.
Eine Zeichnung ist eine Art Zahnrad und ich möchte die Außenkontur ausräumen. Bis zum Punkt FSELECT3 funktioniert das auch alles wunderbar, wenn ich aber dann die beschriebene Kontur inkremental weiterdrehen möchte um die Kontur zu schließen, macht er das nicht und sagt mir meine Angaben wären widersprüchlich. Ich habe das Programm genau so eingegeben wie ihr es hier findet und kann auch keinen Unterschied zur Musterlösung erkennen, aber irgendwo ist ja ein Fehler drin.
0 BEGIN PGM ZAHNRAD MM
1 BLK FORM 0.1 Z X-30 Y-30 Z-10
2 BLK FORM 0.2 X+30 Y+30 Z+0
3 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+1 ;BEZUGSPUNKT-NUMMER
4 TOOL CALL "SF_VHM_5" Z S3000 F3000
5 L X+0 Y+0 FMAX M3
6 L Z+20 FMAX
7 CYCL DEF 14.0 KONTUR
8 CYCL DEF 14.1 KONTURLABEL1 /2
9 CYCL DEF 20 KONTUR-DATEN ~
Q1=-6 ;FRAESTIEFE ~
Q2=+1 ;BAHN-UEBERLAPPUNG ~
Q3=+0 ;AUFMASS SEITE ~
Q4=+0 ;AUFMASS TIEFE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q6=+2 ;SICHERHEITS-ABST. ~
Q7=+20 ;SICHERE HOEHE ~
Q8=+0 ;RUNDUNGSRADIUS ~
Q9=+1 ;DREHSINN
10 CYCL DEF 22 AUSRAEUMEN ~
Q10=-3 ;ZUSTELL-TIEFE ~
Q11=+1500 ;VORSCHUB TIEFENZ. ~
Q12= AUTO ;VORSCHUB RAEUMEN ~
Q18=+0 ;VORRAEUM-WERKZEUG ~
Q19=+0 ;VORSCHUB PENDELN ~
Q208=+99999 ;VORSCHUB RUECKZUG ~
Q401=+100 ;VORSCHUBFAKTOR ~
Q404=+0 ;NACHRAEUMSTRATEGIE
11 CYCL CALL
12 M30
13 LBL 1
14 L X-35 Y-35 RR
15 L Y+35
16 L X+35
17 L Y-35
18 L X-35
19 LBL 0
20 LBL 2
21 FPOL X+0 Y+0
22 FL PR+29 PA+10.055 RL
23 FC R29 DR- CCX+0 CCY+0
24 FC R2.5 PR+29 DR+ CCX+28.892 CCY+0
25 FSELECT3
26 CYCL DEF 10.0 DREHUNG
27 CYCL DEF 10.1 IROT-15
28 CALL LBL 2 REP23
29 LBL 0
30 END PGM ZAHNRAD MM
Ich bitte euch hier mal drüber zu schauen und mir bei der Lösung des Problems zu helfen. Vielen Dank!
Hallo,
dieses Programmierbeispiel ist schon etwas älter und nicht ganz richtig programmiert. Der Startpunkt bei der FK-Programmierung muss nämlich bekannt sein und darf auch nicht durch einen Q-Parameter parametrisiert sein. Wenn der Startpunkt fehlt kann dies zu Fehlern führen. Um dies zu vermeiden prüfen die aktuellen TNC640-, TNC620- und TNC320-Steuerungen die programmierte Kontur genauer.
Da in Deiner FK-Konturbeschreibung der Startpunkt fehlt und im LBL2 gleich mit der Konturbeschreibung in FK begonnen wird, kommt es hier zu diesem Fehler.
Man kann dies aber ganz einfach lösen in dem man diesen wie unten gezeigt nachträglich einfügt.
0 BEGIN PGM ZAHNRAD_NEU MM
1 BLK FORM 0.1 Z X-30 Y-30 Z-10
2 BLK FORM 0.2 X+30 Y+30 Z+0
3 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+1 ;BEZUGSPUNKT-NUMMER
4 TOOL CALL "MILL_D4_ROUGH" Z S3000 F3000
5 L X+0 Y+0 FMAX M3
6 L Z+20 FMAX
7 CYCL DEF 14.0 KONTUR
8 CYCL DEF 14.1 KONTURLABEL1 /2
9 CYCL DEF 20 KONTUR-DATEN ~
Q1=-6 ;FRAESTIEFE ~
Q2=+1 ;BAHN-UEBERLAPPUNG ~
Q3=+0 ;AUFMASS SEITE ~
Q4=+0 ;AUFMASS TIEFE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q6=+2 ;SICHERHEITS-ABST. ~
Q7=+20 ;SICHERE HOEHE ~
Q8=+0 ;RUNDUNGSRADIUS ~
Q9=+1 ;DREHSINN
10 CYCL DEF 22 AUSRAEUMEN ~
Q10=-3 ;ZUSTELL-TIEFE ~
Q11=+1500 ;VORSCHUB TIEFENZ. ~
Q12= AUTO ;VORSCHUB RAEUMEN ~
Q18=+0 ;VORRAEUM-WERKZEUG ~
Q19=+0 ;VORSCHUB PENDELN ~
Q208=+99999 ;VORSCHUB RUECKZUG ~
Q401=+100 ;VORSCHUBFAKTOR ~
Q404=+0 ;NACHRAEUMSTRATEGIE
11 CYCL CALL
12 M30
13 LBL 1
14 L X-35 Y-35 RR
15 L Y+35
16 L X+35
17 L Y-35
18 L X-35
19 LBL 0
20 LBL 2
21 CC X+0 Y+0
22 LP PR+29 PA+10.055 RL
23 LBL 3
24 FPOL X+0 Y+0
25 FC R29 DR- CCX+0 CCY+0
26 FC R2.5 PR+29 DR+ CCX+28.892 CCY+0
27 FSELECT3
28 CYCL DEF 10.0 DREHUNG
29 CYCL DEF 10.1 IROT-15
30 CALL LBL 3 REP23
31 LBL 0
32 END PGM ZAHNRAD_NEU MM
Angehängte Datei(en)
ZAHNRAD_NEU.H ( 1.25KB )
Anzahl der Downloads: 4