584.800 aktive Mitglieder*
4.543 Besucher online*
Kostenfrei registrieren
Anmelden Registrieren
HEIDENHAIN Forum

Ausräumen um eine Insel herum

Beitrag 12.04.2014, 12:23 Uhr
CptCthulu
CptCthulu
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 10.04.2014
Beiträge: 6

Moin Moin Leute,

bin noch ganz frisch hier im Forum und auch noch Frischling an Maschinen mit Heidenhain-Steuerung, deshalb hoffe ich, das ich hier richtig bin und das ihr mir ein wenig helfen könnt. (:

Und zwar habe ich mir hier aus dem Forum die Zeichnung für das Herz heruntergeladen und dieses auch auf der iTnc530 programmiert bekommen, soweit alles gut. Jedoch würde ich nun gerne um diese entstandene Insel herum alles Ausräumen, so das halt nur noch das Herz hervorsteht.
Wenn ich jetzt den Zyklus 14 bzw 14.1 mit dem Konturlabel versehe und danach Zyklus 22 programmiere und aufrufe sagt die Maschine das der Vorschub fehlt, obwohl dieser angegeben ist, ich hoffe ich konnte mich gut genug ausdrücken und irgendjemand kann mir bei meinem Problem helfen.
Schon mal vielen lieben Dank im Voraus!

MfG, Ben
TOP    
Beitrag 12.04.2014, 12:35 Uhr
Snoopy_1993
Snoopy_1993
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 09.06.2012
Beiträge: 1.035

du brauchst auch noch zyklus 20.

stell doch mal das programm rein, dann kann man dir leichter helfen


--------------------
Mein Youtube ►► CNC World ◄◄
________________________________________________________________________________

hyperMill ✔
Hermle C30U ✔
Hermle C50U ✔
Grob G550 mit PSS-R ✔
DMG Mori NTX2000 ✔
TOP    
Beitrag 12.04.2014, 13:02 Uhr
CptCthulu
CptCthulu
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 10.04.2014
Beiträge: 6

Habe mal einen Screenshot davon gemacht, weis nicht wie ich die datei .H sonst öffnen soll. *duck*
Angehängte Datei  Herz.JPG ( 77.58KB ) Anzahl der Downloads: 124
TOP    
Beitrag 12.04.2014, 13:23 Uhr
gekufi
gekufi
Level 7 = Community-Professor
*******
Gruppe: Banned
Mitglied seit: 25.09.2003
Beiträge: 2.393

Hallo

QUOTE
weis nicht wie ich die datei .H sonst öffnen soll. *duck*

Die Datei entweder mittels "PGM MGT" in der Betriebsart "Einspeichern/Editieren" des Programmierplatz/Steuerung oder mittels TNCremo aus der Maschine auslesen in ein Verzeichnis außerhalb des TNC-Pfades oder auf eine andere Festplatte.
Beim Einlesen in die Steuerung oder die Programmierplatzsoftware entsprechend verfahren. Also wieder entweder mittels TNCremo oder in der Software/Steuerung mittels PGM MGT in der Betriebsart "Einspeichern/Editieren".

So hat man dann immer die passende Datei oder das passende Dateiformat. Außerhalb der Steuerung/Programmierplatz eine Textdatei und in der Steuerung/Programmierplatz das passende heidenhaineigene Binärformat.
TNCremo kann man sich bei Heidenhain kostenlos runterladen.

Gruß Gerd

Der Beitrag wurde von gekufi bearbeitet: 12.04.2014, 13:24 Uhr


--------------------
Wer das Konzept der Unendlichkeit verstehen will, muss nur das Ausmaß menschlicher Dummheit betrachten.
Voltaire
TOP    
Beitrag 12.04.2014, 13:28 Uhr
CptCthulu
CptCthulu
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 10.04.2014
Beiträge: 6

Vielen dank Gerd!

Hab jetzt mal den Zyklus 20 beigepackt er sagt mir jedoch immer noch in der Simulation das der Vorschub fehlt....

QUOTE
0 BEGIN PGM Herz MM
1 BLK FORM 0.1 Z X-60 Y+0 Z-10
2 BLK FORM 0.2 X+60 Y+120 Z+0
3 TOOL CALL 2 Z S2000 F120
4 L Z+200 R0 FMAX M3
5 CYCL DEF 14.0 KONTUR
6 CYCL DEF 14.1 KONTURLABEL1
7 CYCL DEF 20 KONTUR-DATEN ~
Q1=-5 ;FRAESTIEFE ~
Q2=+1 ;BAHN-UEBERLAPPUNG ~
Q3=+0 ;AUFMASS SEITE ~
Q4=+0 ;AUFMASS TIEFE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q6=+2 ;SICHERHEITS-ABST. ~
Q7=+50 ;SICHERE HOEHE ~
Q8=+0 ;RUNDUNGSRADIUS ~
Q9=+1 ;DREHSINN
8 CYCL DEF 22 AUSRAEUMEN ~
Q10=-0.75 ;ZUSTELL-TIEFE ~
Q11=+150 ;VORSCHUB TIEFENZ. ~
Q12=+120 ;VORSCHUB RAEUMEN ~
Q18=+0 ;VORRAEUM-WERKZEUG ~
Q19=+0 ;VORSCHUB PENDELN ~
Q208=+99999 ;VORSCHUB RUECKZUG ~
Q401=+100 ;VORSCHUBFAKTOR ~
Q404=+0 ;NACHRAEUMSTRATEGIE
9 CYCL CALL
10 L Z+200
11 CYCL DEF 14.0 KONTUR
12 CYCL DEF 14.1 KONTURLABEL1
13 CYCL DEF 25 KONTUR-ZUG ~
Q1=-5 ;FRAESTIEFE ~
Q3=+0 ;AUFMASS SEITE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q7=+50 ;SICHERE HOEHE ~
Q10=-0.75 ;ZUSTELL-TIEFE ~
Q11=+150 ;VORSCHUB TIEFENZ. ~
Q12=+10 ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART
14 CYCL CALL
15 L Z+200 R0 FMAX M5
16 STOP M9
17 LBL 1
18 APPR CT X+0 Y+5 CCA40 R+20 RL F100
19 L X-47.15 Y+61.19
20 CC X-28 Y+77.26
21 C X-3 Y+77.26 DR-
22 CC X+0 Y+77.26
23 C X+3 Y+77.26 DR+
24 CC X+28 Y+77.26
25 C X+47.15 Y+61.19 DR-
26 L X+0 Y+5
27 DEP LT LEN35
28 LBL 0
29 END PGM Herz MM
TOP    
Beitrag 12.04.2014, 15:38 Uhr
homerq
homerq
Level 5 = Community-Ingenieur
*****
Gruppe: Mitglied
Mitglied seit: 03.06.2004
Beiträge: 737

QUOTE (CptCthulu @ 12.04.2014, 13:28 Uhr) *
Vielen dank Gerd!

Hab jetzt mal den Zyklus 20 beigepackt er sagt mir jedoch immer noch in der Simulation das der Vorschub fehlt....

Hallo!
Erstmal gibt es beim Ausräumen keine An und Abfahrfunktionen! Hier also nur RR/RL und am Konturende nichts (die Kontur muß geschlossen sein).
Dann mußt du eine zweite Kontur beschreiben, hier die Tasche als LBL 2 meinetwegen. Hier wäre die Blockform + Fräserrad. richtig, die Insel ist dein Herz.
Die Konturen müssen unterschiedliche Richtungen haben (Üblicherweise RL und RR, wenn man gleichlauf programmiert)! Deine Insel ist gegenlauf, dann RL.
Der Rahmen wäre dann:
lbl2
l x65 y-5 rl
l y125
l x-65
l y-5
l x65
lbl0
Im Zyklus 14 muß dann noch lbl2 angegeben werden.
F0 beim Vorschub Pendeln erzeugt ein senkrechtes Eintauchen hier noch einen Vorschub rein, und das Werkzeug pendelt in Z (werkzeugschonender).
So sollte es funktionieren.
Viel Erfolg

Gruß Jens
P.S. Endlich mal ein Fräser mit Herz thumbs-up.gif
TOP    
Beitrag 12.04.2014, 15:54 Uhr
VHMler
VHMler
Level 2 = Community-Facharbeiter
**
Gruppe: Mitglied
Mitglied seit: 06.12.2012
Beiträge: 148

Mahlzeit,

hab mir mal dein PGM auf´n Programmierplatz laufen lassen:

Um das Restmaterial auszuräumen muss um deine Insel herum eine Tasche in einem LBL ( z.B.: LBL 2) definiert sein und im Zyklus 14 eingetragen sein .
Diese ist im Gegenlauf zu proggen (Umlaufsinn im LBL und mit RR programmiert )
Bsp.:

LBL 2
L X-65 Y-5 RR
L Y+135
L X+65
L Y-5
L X-65
LBL 0


Der Ausräumzyklus mag keine APPR/DEP Sätze in den Konturlabels d.h.: Anstelle von APPR CT und zum Schluss einfach der Eckpunkt, hier X0 Y5 angegeben.
Um beim 25 er Zyklus dennoch weich anfahren zu können gibt es auf der 530 den Zyklus 270. Der wird zwischen Zyklus 14 und 25 eingetragen.
Bsp.:

LBL 1
L X+0 Y+5 RL
L X-47.15 Y+61.19
CC X-28 Y+77.26
C X-3 Y+77.26 DR-
CC X+0 Y+77.26
C X+3 Y+77.26 DR+
CC X+28 Y+77.26
C X+47.15 Y+61.19 DR-
L X+0 Y+5
LBL 0

Bezüglich fehlenden Vorschubs hab ich keine Fehlermeldung bekommen. Habe nur die Tasche (im LBL 2) und den Zyklus 14 auf LBL 1 und 2 gesetzt
Bsp.:

CYCL DEF 14.0 KONTUR
CYCL DEF 14.1 KONTURLABEL1 /2 -------> mit Enter weiterschalten


Habs hoffentlich verständlich geschrieben.

Gruß VHMler

Da war wohl ein anderer schneller, hab ich wohl zu lange in die Tasten gehauen. Naja soll ja mal vorkommen

Der Beitrag wurde von VHMler bearbeitet: 12.04.2014, 15:56 Uhr


--------------------
Was denkbar ist, ist machbar! .... Oder auch nicht?
TOP    
Beitrag 12.04.2014, 15:58 Uhr
V4Aman
V4Aman
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 03.06.2010
Beiträge: 2.602

Ja, der Vorschub fehlt ja auch im Satz 10 wink.gif

0 BEGIN PGM Herz MM
1 BLK FORM 0.1 Z X-60 Y+0 Z-10
2 BLK FORM 0.2 X+60 Y+120 Z+0
3 TOOL CALL 2 Z S2000 F120
4 L Z+200 R0 FMAX M3
5 CYCL DEF 14.0 KONTUR
6 CYCL DEF 14.1 KONTURLABEL1
7 CYCL DEF 20 KONTUR-DATEN ~
Q1=-5 ;FRAESTIEFE ~
Q2=+1 ;BAHN-UEBERLAPPUNG ~
Q3=+0 ;AUFMASS SEITE ~
Q4=+0 ;AUFMASS TIEFE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q6=+2 ;SICHERHEITS-ABST. ~
Q7=+50 ;SICHERE HOEHE ~
Q8=+0 ;RUNDUNGSRADIUS ~
Q9=+1 ;DREHSINN
8 CYCL DEF 22 AUSRAEUMEN ~
Q10=-0.75 ;ZUSTELL-TIEFE ~
Q11=+150 ;VORSCHUB TIEFENZ. ~
Q12=+120 ;VORSCHUB RAEUMEN ~
Q18=+0 ;VORRAEUM-WERKZEUG ~
Q19=+0 ;VORSCHUB PENDELN ~
Q208=+99999 ;VORSCHUB RUECKZUG ~
Q401=+100 ;VORSCHUBFAKTOR ~
Q404=+0 ;NACHRAEUMSTRATEGIE
9 CYCL CALL
10 L Z+200
11 CYCL DEF 14.0 KONTUR
12 CYCL DEF 14.1 KONTURLABEL1
13 CYCL DEF 25 KONTUR-ZUG ~
Q1=-5 ;FRAESTIEFE ~
Q3=+0 ;AUFMASS SEITE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q7=+50 ;SICHERE HOEHE ~
Q10=-0.75 ;ZUSTELL-TIEFE ~
Q11=+150 ;VORSCHUB TIEFENZ. ~
Q12=+10 ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART
14 CYCL CALL
15 L Z+200 R0 FMAX M5
16 STOP M9


--------------------
Gruß V4Aman


__________________________________________________________________________

Alle sagten: "Das geht nicht." Dann kam einer, der wusste das nicht, und hat's einfach gemacht.
TOP    
Beitrag 12.04.2014, 17:29 Uhr
CptCthulu
CptCthulu
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 10.04.2014
Beiträge: 6

Schon mal viele dank für die ganzen Antworten, werde mich da morgen Abend oder Montag mal vor setzen und es mal so probieren wie ihr es mir beschrieben habt. (:

Gruß!
TOP    
Beitrag 13.04.2014, 08:08 Uhr
Stefan21178
Stefan21178
Level 6 = Community-Doktor
******
Gruppe: Mitglied
Mitglied seit: 01.07.2006
Beiträge: 802

@ V4Aman
QUOTE
Ja, der Vorschub fehlt ja auch im Satz 10 wink.gif

Stimmt nur zum Teil. Wenn kein Vorschub angegeben ist, nimmt die Maschine den aus dem Tool Call Satz
3 TOOL CALL 2 Z S2000 F120


--------------------
Frohe Grüsse Stefan

Ein Tag ohne lächeln ist ein verlorener Tag
TOP    
Beitrag 13.04.2014, 10:03 Uhr
V4Aman
V4Aman
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 03.06.2010
Beiträge: 2.602

Dann muß aber ein FAUTO geschrieben sein oder....?


--------------------
Gruß V4Aman


__________________________________________________________________________

Alle sagten: "Das geht nicht." Dann kam einer, der wusste das nicht, und hat's einfach gemacht.
TOP    
Beitrag 13.04.2014, 10:47 Uhr
VHMler
VHMler
Level 2 = Community-Facharbeiter
**
Gruppe: Mitglied
Mitglied seit: 06.12.2012
Beiträge: 148

Mahlzeit,

es muss nicht zwingend ein Vorschub eingetragen sein.

Hatte auch mal bei meiner Maschine einen FMAX vergessen und siehe da, die Maschine verfährt mit dem Programmierten Vorschub.


Dauert zwar etwas Länger aber man kommt auch ans Ziel


Einen schönen Sonntag wünscht


VHMler


--------------------
Was denkbar ist, ist machbar! .... Oder auch nicht?
TOP    
Beitrag 13.04.2014, 11:27 Uhr
V4Aman
V4Aman
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 03.06.2010
Beiträge: 2.602

Ja schon, aber nur wenn in einem vorher eingeglesenen Satz schon ein Vorschub stand. FMAX gilt da nicht.


--------------------
Gruß V4Aman


__________________________________________________________________________

Alle sagten: "Das geht nicht." Dann kam einer, der wusste das nicht, und hat's einfach gemacht.
TOP    
Beitrag 13.04.2014, 12:01 Uhr
cgTNC
cgTNC
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 21.11.2010
Beiträge: 1.341

QUOTE (V4Aman @ 13.04.2014, 11:27 Uhr) *
Ja schon, aber nur wenn in einem vorher eingeglesenen Satz schon ein Vorschub stand. FMAX gilt da nicht.

Ich schreibe normalerweise nie FAUTO ins Programm, außer ich möchte für einzelne Sätze einen anderen Vorschub als beim TOOL CALL angegeben verwenden.

Ansonsten wie schon von den Anderen beschrieben:
FMAX gilt nur Satzweise, also nur für den Satz in dem FMAX steht.
Ohne Voschubangabe wird der zuletzt gültige Fräsvorschub verwendet. Wenn man nur der Vorschub vom TOOL CALL verwenden möchte braucht man nix angeben.

Bei einer DIN-Steuerung würde man für L .. FMAX ein G0 schreiben.
L .. F .. gilt bei der Heidenhain als G1, wobei ein L ohne Vorschubangabe auch immer G1 ist.

Gruß
cgTNC

Der Beitrag wurde von cgTNC bearbeitet: 13.04.2014, 12:14 Uhr
TOP    
Beitrag 13.04.2014, 12:19 Uhr
homerq
homerq
Level 5 = Community-Ingenieur
*****
Gruppe: Mitglied
Mitglied seit: 03.06.2004
Beiträge: 737

QUOTE (cgTNC @ 13.04.2014, 12:01 Uhr) *
Ich schreibe normalerweise nie FAUTO ins Programm, außer ich möchte für einzelne Sätze einen anderen Vorschub als beim TOOL CALL angegeben verwenden.

Ansonsten wie schon von den Anderen beschrieben:
FMAX gilt nur Satzweise, also nur für den Satz in dem FMAX steht.
Ohne Voschubangabe wird der zuletzt gültige Fräsvorschub verwendet. Wenn man nur der Vorschub vom TOOL CALL verwenden möchte braucht man nix angeben.

Gruß
cgTNC

Hallo!
Also ich hab`s durchgespielt, in dem Satz lag wohl der Fehler nicht. Das ist mal wieder so eine abartige, nichtssagende Fehlermeldung von hh.
Aber es gibt wohl keine Konkurenz am Markt, da braucht man ja nicht auf die meckernde Masse eingehen.
Mit den erwähnten Tipps wird der Fragesteller endlich seiner Geliebten sein Herz in Alu überreichen können .... Träum! ... wie romantisch!
Gruß Jens
TOP    
Beitrag 13.04.2014, 14:03 Uhr
cgTNC
cgTNC
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 21.11.2010
Beiträge: 1.341

QUOTE (homerq @ 12.04.2014, 15:38 Uhr) *
Dann mußt du eine zweite Kontur beschreiben, hier die Tasche als LBL 2 meinetwegen. Hier wäre die Blockform + Fräserrad. richtig, die Insel ist dein Herz.
Die Konturen müssen unterschiedliche Richtungen haben (Üblicherweise RL und RR, wenn man gleichlauf programmiert)! Deine Insel ist gegenlauf, dann RL.

Ob die Aussenkontur und das Herz mit RL oder RR programmiert werden ist egal, sie können beide die gleiche Richtung haben.
Es kommt darauf an, das die Fräserbahnen innerhalb der Aussenkontur und ausserhalb der Insel (Herz) programmiert werden.

QUOTE (VHMler @ 12.04.2014, 15:54 Uhr) *
Der Ausräumzyklus mag keine APPR/DEP Sätze in den Konturlabels d.h.: Anstelle von APPR CT und zum Schluss einfach der Eckpunkt, hier X0 Y5 angegeben.
Um beim 25 er Zyklus dennoch weich anfahren zu können gibt es auf der 530 den Zyklus 270. Der wird zwischen Zyklus 14 und 25 eingetragen.

Für Zyklus 22 müssen die APPR/DEP-Sätze wie beschrieben aus dem LBL 1 heraus genommen werden, dann ist auch der Fehler mit dem fehlenden Vorschub weg.

Alternativ zu Zyklus 270 kann für Zyklus 25 ein kurzes drittes LBL programmiert werden, dann sind auch unterschiedlich An- und Abfahrwege programmierbar:
LBL 3
APPR CT X+0 Y+5 CCA40 R+20 RL
CALL LBL 1
DEP LT LEN35
LBL 0

Gruß
cgTNC
TOP    
Beitrag 13.04.2014, 16:05 Uhr
macmaddog
macmaddog
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 13.07.2005
Beiträge: 1.316

Q19 in Satz 8?
Regel 1:
Konturbeschreibungen immer schneidend programmieren, nie tangierend.
Regel 2 :
Immer gleiche Richtung der Konturbeschreibungen.
Du kannst die Label hinter den M30 schreiben.
Wenn du Außen herum Freiräumen willst, dann Äußere Taschenbeschreibung als Konturlabel mit FR Radius + 1 größer programmieren.

Der Beitrag wurde von macmaddog bearbeitet: 13.04.2014, 16:12 Uhr


--------------------
"Bei weiteren Fragen einfach im Chat melden. mfG macmaddog. "
TOP    
Beitrag 13.04.2014, 16:13 Uhr
schwindl
schwindl
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 18.09.2008
Beiträge: 2.311

Hallo CptCthulu,

zum Thema SL-Tyklen gibts ein Webinar Link

Ausserdem noch weiter interessante Webinare über Programmierthemen von HEIDENHAIN.


--------------------
Gruß
Schwindl
TOP    
Beitrag 13.04.2014, 16:14 Uhr
V4Aman
V4Aman
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 03.06.2010
Beiträge: 2.602

Wenn im Q19 mit 0 definiert ist benutzt die Steuerung das gerade eintauchen vom Q11


--------------------
Gruß V4Aman


__________________________________________________________________________

Alle sagten: "Das geht nicht." Dann kam einer, der wusste das nicht, und hat's einfach gemacht.
TOP    
Beitrag 13.04.2014, 16:20 Uhr
schwindl
schwindl
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 18.09.2008
Beiträge: 2.311

QUOTE (macmaddog @ 13.04.2014, 16:05 Uhr) *
Q19 in Satz 8?
Regel 1:
Konturbeschreibungen immer schneidend programmieren, nie tangierend.
Regel 2 :
Immer gleiche Richtung der Konturbeschreibungen.
Du kannst die Label hinter den M30 schreiben.
Wenn du Außen herum Freiräumen willst, dann Äußere Taschenbeschreibung als Konturlabel mit FR Radius + 1 größer programmieren.

Q19 im Satz 8 is Ok, dann sticht der Fräser in Z- ein und pendelt nicht.
Nicht gut fürs Werkzeug, wenn nicht vorgebohrt wurde.

Regel 2 ist hilfreich aber nicht zwingend notwendig, es geht auch in unterschiedliche richtung.


--------------------
Gruß
Schwindl
TOP    
Beitrag 15.04.2014, 12:51 Uhr
CptCthulu
CptCthulu
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 10.04.2014
Beiträge: 6

Ich bin glaube noch zu unversiert in der ganzen Sache, ich bekomme das einfach nicht hin, habe jet ein weiteres Label angelegt um um die insel herum zu Räumen jedoch kommt immer wieder ein Fehler, egal was ich mache. :/
Bitte um Hilfe für nen bitteren Anfänger. biggrin.gif

QUOTE
0 BEGIN PGM Herz MM
1 BLK FORM 0.1 Z X-60 Y+0 Z-10
2 BLK FORM 0.2 X+60 Y+120 Z+0
3 TOOL CALL 2 Z S2000 F120 DR+0.2
4 L Z+200 R0 FMAX M3
5 CYCL DEF 14.0 KONTUR
6 CYCL DEF 14.1 KONTURLABEL2 /1
7 CYCL DEF 20 KONTUR-DATEN ~
Q1=-5 ;FRAESTIEFE ~
Q2=+1 ;BAHN-UEBERLAPPUNG ~
Q3=+0 ;AUFMASS SEITE ~
Q4=+0 ;AUFMASS TIEFE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q6=+2 ;SICHERHEITS-ABST. ~
Q7=+50 ;SICHERE HOEHE ~
Q8=+1 ;RUNDUNGSRADIUS ~
Q9=+1 ;DREHSINN
8 CYCL DEF 22 AUSRAEUMEN ~
Q10=-0.75 ;ZUSTELL-TIEFE ~
Q11=+150 ;VORSCHUB TIEFENZ. ~
Q12=+120 ;VORSCHUB RAEUMEN ~
Q18=+0 ;VORRAEUM-WERKZEUG ~
Q19=+150 ;VORSCHUB PENDELN ~
Q208=+99999 ;VORSCHUB RUECKZUG ~
Q401=+100 ;VORSCHUBFAKTOR ~
Q404=+0 ;NACHRAEUMSTRATEGIE
9 CYCL CALL
10 L Z+200 FMAX
11 CYCL DEF 14.0 KONTUR
12 CYCL DEF 14.1 KONTURLABEL1
13 CYCL DEF 25 KONTUR-ZUG ~
Q1=-5 ;FRAESTIEFE ~
Q3=+0 ;AUFMASS SEITE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q7=+50 ;SICHERE HOEHE ~
Q10=-0.75 ;ZUSTELL-TIEFE ~
Q11=+150 ;VORSCHUB TIEFENZ. ~
Q12=+10 ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART
14 CYCL CALL
15 L Z+200 R0 FMAX M5
16 STOP M9
17 LBL 1
18 APPR CT X+0 Y+5 CCA40 R+20 RL F100
19 L X-47.15 Y+61.19 RL
20 CC X-28 Y+77.26
21 C X-3 Y+77.26 DR-
22 CC X+0 Y+77.26
23 C X+3 Y+77.26 DR+
24 CC X+28 Y+77.26
25 C X+47.15 Y+61.19 DR-
26 L X+0 Y+5
27 DEP LT LEN35
28 LBL 0
29 LBL 2
30 L X+65 Y-5 RL
31 L Y+125
32 L X-65
33 L Y-5
34 L X+65
35 LBL 0
36 END PGM Herz MM
TOP    
Beitrag 15.04.2014, 13:14 Uhr
Vance Legstrong
Vance Legstrong
Level 2 = Community-Facharbeiter
**
Gruppe: Mitglied
Mitglied seit: 09.07.2004
Beiträge: 113

QUOTE (CptCthulu @ 15.04.2014, 12:51 Uhr) *
Ich bin glaube noch zu unversiert in der ganzen Sache, ich bekomme das einfach nicht hin, habe jet ein weiteres Label angelegt um um die insel herum zu Räumen jedoch kommt immer wieder ein Fehler, egal was ich mache. :/
Bitte um Hilfe für nen bitteren Anfänger. biggrin.gif



was mir als erstes auffällt:

ein fehlendes M30 in Satz 16

in Satz 18 hat der F150 nichts zu suchen
TOP    
Beitrag 15.04.2014, 13:30 Uhr
Vance Legstrong
Vance Legstrong
Level 2 = Community-Facharbeiter
**
Gruppe: Mitglied
Mitglied seit: 09.07.2004
Beiträge: 113

QUOTE (Vance Legstrong @ 15.04.2014, 13:14 Uhr) *
was mir als erstes auffällt:

ein fehlendes M30 in Satz 16

in Satz 18 hat der F150 nichts zu suchen



so funzt es:

0 BEGIN PGM Herz MM
1 BLK FORM 0.1 Z X-60 Y+0 Z-10
2 BLK FORM 0.2 X+60 Y+120 Z+0
3 TOOL CALL 1 Z S2000 DL+0 DR+0.2
4 L M13
5 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+1 ;BEZUGSPUNKT-NUMMER
6 CYCL DEF 14.0 KONTUR
7 CYCL DEF 14.1 KONTURLABEL1 /2
8 CYCL DEF 20 KONTUR-DATEN ~
Q1=-5 ;FRAESTIEFE ~
Q2=+1 ;BAHN-UEBERLAPPUNG ~
Q3=+0 ;AUFMASS SEITE ~
Q4=+0 ;AUFMASS TIEFE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q6=+2 ;SICHERHEITS-ABST. ~
Q7=+50 ;SICHERE HOEHE ~
Q8=+0 ;RUNDUNGSRADIUS ~
Q9=+1 ;DREHSINN
9 CYCL DEF 21 VORBOHREN ~
Q10=-1 ;ZUSTELL-TIEFE ~
Q11=+500 ;VORSCHUB TIEFENZ. ~
Q13=+0 ;AUSRAEUM-WERKZEUG
10 CYCL CALL
11 CYCL DEF 22 AUSRAEUMEN ~
Q10=-7.5 ;ZUSTELL-TIEFE ~
Q11=+500 ;VORSCHUB TIEFENZ. ~
Q12=+1200 ;VORSCHUB RAEUMEN ~
Q18=+0 ;VORRAEUM-WERKZEUG ~
Q19=+0 ;VORSCHUB PENDELN ~
Q208=+99999 ;VORSCHUB RUECKZUG ~
Q401=+100 ;VORSCHUBFAKTOR ~
Q404=+0 ;NACHRAEUMSTRATEGIE
12 CYCL CALL
13 L Z+200 R0 FMAX M5
14 STOP M30
15 LBL 1
16 L X+0 Y+5 RL
17 L X-47.15 Y+61.19 RL
18 CC X-28 Y+77.26
19 C X-3 Y+77.26 DR-
20 CC X+0 Y+77.26
21 C X+3 Y+77.26 DR+
22 CC X+28 Y+77.26
23 C X+47.15 Y+61.19 DR-
24 L X+0 Y+5
25 LBL 0
26 LBL 2
27 L X+65 Y-5 RL
28 L Y+125
29 L X-65
30 L Y-5
31 L X+65
32 LBL 0
33 END PGM Herz MM
TOP    
Beitrag 15.04.2014, 16:51 Uhr
CptCthulu
CptCthulu
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 10.04.2014
Beiträge: 6

Cool, danke! smile.gif

Könntest du kurz erläutern was du geändert hast damit ich auch was draus lernen kann.^^

Vielen dank,
Gruß CptCthulu
TOP    
Beitrag 15.04.2014, 18:55 Uhr
VHMler
VHMler
Level 2 = Community-Facharbeiter
**
Gruppe: Mitglied
Mitglied seit: 06.12.2012
Beiträge: 148

QUOTE (CptCthulu @ 15.04.2014, 16:51 Uhr) *
Cool, danke! smile.gif

Könntest du kurz erläutern was du geändert hast damit ich auch was draus lernen kann.^^

Vielen dank,
Gruß CptCthulu



Nabend,


vergleich einfach mal dein Programm mit jenem von Vance Legstrong und erzähl uns was dir auffällt. Somit zeigst du uns, das du das PGM nicht nur
einfach Kopierst und Einfügst und es dir nicht mal ansiehst.

Bitte nicht falsch verstehen, hier wird gern geholfen, wenn erkennbar ist das der Themenstarter
oder Fragensteller selbst mitdenkt und nicht nur fertige PGM übernimmt.

Gruß VHMler


@Vance Legstrong: ein Gefinkelter Schachzug von dir ! wenn auch nicht ohne

Der Beitrag wurde von VHMler bearbeitet: 15.04.2014, 18:58 Uhr


--------------------
Was denkbar ist, ist machbar! .... Oder auch nicht?
TOP    



1 Besucher lesen dieses Thema (Gäste: 1)
0 Mitglieder: