584.829 aktive Mitglieder*
5.150 Besucher online*
Kostenfrei registrieren
Anmelden Registrieren
HEIDENHAIN Forum

Unterseite Plan ausrichten

Beitrag 08.04.2020, 21:15 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Hi Community,

gibt es eine Möglichkeit die Unterseite anzutasten und auszurichten und im geschwenkten Zustand die Mitte von rotationssymetrischen Werkstücken zusetzen?

Physikalische Achsen C und A mit TNC640

Danke schonmal
TOP    
Beitrag 08.04.2020, 21:51 Uhr
schwindl
schwindl
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 18.09.2008
Beiträge: 2.311

Kommst du an die Unterseite im geschwenkten System mit dem Taster ran?


--------------------
Gruß
Schwindl
TOP    
Beitrag 08.04.2020, 22:27 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Ja, an 3 Punkten. Es wird im Futter gespannt. Wenn ich normal die Ebene taste muss ich beim 431‘er, wenn ich TCPM nutze, darf ich zwischen den ersten 2 Punkten nur in X+ verfahren.
Beim M128 musste man doch bloß darauf achten in positiver Richtung zu verfahren? Oder lieg ich da falsch?
Zumindest hatte das immer funktioniert.

Danke

Der Beitrag wurde von Smyrre bearbeitet: 08.04.2020, 22:28 Uhr
TOP    
Beitrag 09.04.2020, 07:28 Uhr
schwindl
schwindl
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 18.09.2008
Beiträge: 2.311

Du könntest im geschwenkten System in drei Punkten einen Bezugspunkt setzen, in Preset 1,2,3. Dann rechnet er dir das in das ungeschwenkte System zurück.
Anschließend liest du dir die drei Punkte aus und richtest das Teil über Plane Points aus.
DIE FN18 zum Lesen der Presettabelle stehen im Benutzerhandbuch.


--------------------
Gruß
Schwindl
TOP    
Beitrag 09.04.2020, 07:56 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Danke, so hatte ich das für den Nullpunkt geplant.
TOP    
Beitrag 19.04.2020, 00:47 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Mit Plane Points hat’s super funktioniert! Ich habe nur eine Bezugspunkttabelle verwendet.
Jetzt versuche ich mit TCPM gerade zu stellen (erstmal auf der Oberseite ������) .
Das funktioniert auch mit Plane Spatial A+Q170 B+Q171 C+Q172 geradezustellen. Dann taste ich die Oberfläche in mindestens 3Punkten und habe einen Unterschied von ein paar μm.
Soweit so gut!
Wenn ich das dann über Cycle DEF 330 in die Tabelle eintragen lasse und dann zurückschwenke, egal ob mit Plane Reset oder L A+0 C+0 , dann wieder mit Plane Spatial A+0 B+0 C+0 hindrehe steht die Fläche gerade (mit Meßuhr geprüft), aber mit dem Taster bekomme ich quere Ergebnisse.
Dann probiert mit Plane Spatial A+Q170 B+Q171 C+Q172 das Koordinatensystem anzugleichen, nichts. Sie tastet immer noch quer!
Wenn ich mit Cycle DEF 330 die Achsen wieder nulle, in Ausgangsposition mit Plane Reset oder L A+0 C+0 schwenke, und dann mit Plane Spatial A+Q170 B+Q171 C+Q172 wieder anfahre, passt das mit dem Koordinatensystem wieder.

Übersehe ich was oder muss ich dann meine Schwenkung sag ich mal A-90 bei Q170 dazurechnen?
Ich dachte das man nach dem tasten normal schreibt!?

Ich hoffe das ist verständlich!? ������
Und danke schon mal!!

Der Beitrag wurde von Smyrre bearbeitet: 19.04.2020, 00:50 Uhr
TOP    
Beitrag 19.04.2020, 06:36 Uhr
schwindl
schwindl
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 18.09.2008
Beiträge: 2.311

Stell mal dein Programm ein. Wird die 3D-Grunddrehung in die Presettabelle eingetragen?
Wenn die 3D-Grunddrehung aktiviert ist, kommst du mit PLANE Spatial SPA0 SPB0 SPC0 auf deine ausgerichtete Oberseite.
L A0 C0 oder PLANE RESET drehen die Achsen auf Bezugspunkt 0 zurück.
Was steht nach deinem Plane Points im 3D-ROT?


--------------------
Gruß
Schwindl
TOP    
Beitrag 19.04.2020, 10:22 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

0 BEGIN PGM OBERSEITE_TCPM MM
1 * - ******************************************
2 * - Oberseite TCPM tasten
3 * - ******************************************
4 QR1 = 20 ; Bezugspunkttabelle Rota-S_tasten
5 Q1650 = 0 ; Inkrementale Drehung Koordinatensystem
6 ; - ******************************************
7 FUNCTION MODE MILL
8 ; - *****************************************
9 QR400 = 0 ; Antastpunkt Y
10 QR401 = 100 ; Antastpunkt X+
11 ; - ******************************************
12 QR200 = 60 ; Gradzahl tasten
13 ; - ******************************************
14 QR10 = 0 ; Freifahren in X rechts
15 QR11 = 250 ; Freifahren in Y auf Mitte
16 QR12 = 800 ; Freifahren in Y hinten
17 ; - ******************************************
18 FUNCTION MODE MILL
19 ; - *****************************************
20 QR403 = QR401 * SIN QR200
21 QR404 = QR401 * COS QR200
22 ;
23 ; - *****************************************
24 ;
25 * - Messtaster
26 TOOL CALL "MESSTASTER" Z
27 M140 MB MAX
28 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+QR1 ;BEZUGSPUNKT-NUMMER
29 M25 M27
30 CYCL DEF 330 Werte in Preset ~
Q1525=+0 ;löschen/schreiben
31 PLANE RESET STAY
32 L A+0 C+0 R0 FMAX
33 ;
34 TCH PROBE 431 MESSEN EBENE ~
Q263=-QR404 ;1. PUNKT 1. ACHSE ~
Q264=-QR403 ;1. PUNKT 2. ACHSE ~
Q294=+5 ;1. PUNKT 3. ACHSE ~
Q265=+QR404 ;2. PUNKT 1. ACHSE ~
Q266=-QR403 ;2. PUNKT 2. ACHSE ~
Q295=+5 ;2. PUNKT 3. ACHSE ~
Q296=+QR400 ;3. PUNKT 1. ACHSE ~
Q297=+QR401 ;3. PUNKT 2. ACHSE ~
Q298=+5 ;3. PUNKT 3. ACHSE ~
Q320=+0 ;SICHERHEITS-ABST. ~
Q260=+200 ;SICHERE HOEHE ~
Q281=+0 ;MESSPROTOKOLL
35 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+QR1 ;BEZUGSPUNKT-NUMMER
36 L Z+200 R0 FMAX
37 L X+0 Y+0 R0 FMAX
38 ; - *****************************************
39 ;
40 QR170 = Q170
41 QR171 = Q171
42 QR172 = Q172
43 ;
44 PLANE SPATIAL SPA+QR170 SPB+QR171 SPC+QR172 TURN FMAX SEQ- TABLE ROT
45 ;
46 M0
47 ;
48 CYCL DEF 330 Werte in Preset ~
Q1525=+1 ;löschen/schreiben
49 ;
50 CYCL DEF 10.0 DREHUNG
51 CYCL DEF 10.1 ROT+Q1650
52 TCH PROBE 412 BZPKT KREIS INNEN ~
Q321=+0 ;MITTE 1. ACHSE ~
Q322=+0 ;MITTE 2. ACHSE ~
Q262=+150 ;SOLL-DURCHMESSER ~
Q325=+0 ;STARTWINKEL ~
Q247=+90 ;WINKELSCHRITT ~
Q261=-5 ;MESSHOEHE ~
Q320=+5 ;SICHERHEITS-ABST. ~
Q260=+50 ;SICHERE HOEHE ~
Q301=+1 ;FAHREN AUF S. HOEHE ~
Q305=+QR1 ;NR. IN TABELLE ~
Q331=+0 ;BEZUGSPUNKT ~
Q332=+0 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE ~
Q381=+1 ;ANTASTEN TS-ACHSE ~
Q382=+0 ;1. KO. FUER TS-ACHSE ~
Q383=-90 ;2. KO. FUER TS-ACHSE ~
Q384=+0 ;3. KO. FUER TS-ACHSE ~
Q333=+0 ;BEZUGSPUNKT ~
Q423=+4 ;ANZAHL ANTASTUNGEN ~
Q365=+1 ;VERFAHRART
53 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+QR1 ;BEZUGSPUNKT-NUMMER
54 ;
55 M0
56 ;
57 CALL PGM TNC:\PROGRAMME\NPV-Reset_Fraesen.H
58 ;
59 ; - *****************************************
60 * - >>> ENDE <<<
61 CYCL DEF 330 Werte in Preset ~
Q1525=+0 ;löschen/schreiben
62 M30 M31
63 ; - *****************************************
64 END PGM OBERSEITE_TCPM MM
TOP    
Beitrag 19.04.2020, 10:25 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Ich bin hier ab Satz #46 ins MDI gegangen und hab da dann probiert.
TOP    
Beitrag 19.04.2020, 13:42 Uhr
schwindl
schwindl
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 18.09.2008
Beiträge: 2.311

Ist um Manuellen Betrieb das Schwenken eingeschaltet? 3D-ROT aktiv?


--------------------
Gruß
Schwindl
TOP    
Beitrag 19.04.2020, 18:53 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Werde ich beim nächsten Mal testen, ob es ein- oder ausgeschaltet ist, bei den verschiedenen Modi.

Danke dir dafür, das du sogar am Wochenende die Zeit dafür nimmst!!!

Der Beitrag wurde von Smyrre bearbeitet: 19.04.2020, 18:55 Uhr
TOP    
Beitrag 11.03.2022, 16:14 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Hi Schwindl,

wo hinterlegt die Steuerung die einzelnen Punkte?
In welche Parameter?


Edit: gefunden ������������

Der Beitrag wurde von Smyrre bearbeitet: 11.03.2022, 16:26 Uhr
TOP    
Beitrag 11.03.2022, 16:49 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Ich habe jetzt die Messwerte von der einzelnen Achse (Q160) auf die jeweiligen Messwerte von der Ebene Tasten (Q173/ 174/ 175) geschrieben.
Wie bekomme ich die 3 Punkte, für die Raumwinkel Q170/ 171/ 172, verrechnet?
Wie verrechnet der Zyklus431 diese Punkte?

Der Beitrag wurde von Smyrre bearbeitet: 11.03.2022, 16:51 Uhr
TOP    
Beitrag 11.03.2022, 17:50 Uhr
schwindl
schwindl
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 18.09.2008
Beiträge: 2.311

Hallo, der Zyklus 431 tastet drei Punkte und berrechnet daraus die Raumwinkel Q170,Q171,Q172.
Was Du brauchst ist die Funktion Plane Points, da gibst du die Sollpunkte in XY ein und die getasteten Punkt in Z.


--------------------
Gruß
Schwindl
TOP    
Beitrag 11.03.2022, 19:34 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Danke dir, hat super funktioniert!

Der Beitrag wurde von Smyrre bearbeitet: 11.03.2022, 19:35 Uhr
TOP    
Beitrag 11.03.2022, 21:42 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Hier mal das PGM, vielleicht gibt´s noch etwas zu verbessern.



0 BEGIN PGM UNTERSEITE_TASTEN MM
1 FUNCTION MODE MILL
2 * - ******************************************
3 * - Unterseite antasten und gerade stellen mit Einzelne Achse tasten und Plane Points
4 * - ******************************************
5 ; - Aufbau:
6 ; - ROTA-S_flex ohne Tuerme mit harten >geschliffenen< Backen (2.Treppe)
7 ; - Kurze Grundbacken >normal< herum einschieben (6.Stufe-->8mm)
8 ; - Einstellrin Dm175x31,2
9 ; - 10Nm
10 ; - NP mittig
11 ;
12 ;*********************************************
13 QR1 = 24 ; Bezugspunkttabelle G_2.Treppe
14 QR2 = 18 ; Bezugspunkttabelle ROTA-S_tasten
15 ;*********************************************
16 QR10 = 0 ; Freifahren in X rechts
17 QR11 = 400 ; Freifahren in Y auf Mitte
18 QR12 = 800 ; Freifahren in Y hinten
19 FN 17: SYSWRITE ID 507 NRQR2 IDX1 =+0 ; X-Achse 0 setzen
20 FN 17: SYSWRITE ID 507 NRQR2 IDX2 =+0 ; Y-Achse 0 setzen
21 ;
22 FN 18: SYSREAD QR100 = ID508 NR15 IDX6 ; C_OFFS aus der Bezugspunkttabelle Kinematik auslesen!
23 FN 17: SYSWRITE ID 508 NRQR1 IDX6 =+QR100 ; C_OFFS in die aktuelle Bezugspunkttabelle einschreiben!
24 FN 17: SYSWRITE ID 508 NRQR2 IDX6 =+QR100 ; C_OFFS in die aktuelle Bezugspunkttabelle einschreiben!
25 ;
26 FN 18: SYSREAD QR101 = ID507 NRQR1 IDX3
27 FN 17: SYSWRITE ID 507 NRQR2 IDX3 =+QR101
28 ;*********************************************
29 * - MESSTASTER
30 TOOL CALL "MESSTASTER" Z
31 M140 MB MAX
32 M25 M27
33 ;
34 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+QR2 ;BEZUGSPUNKT-NUMMER
35 CYCL DEF 330 Werte in Preset ~
Q1525=+0 ;löschen/schreiben
36 PLANE RESET STAY
37 L A+0 C+0 R0 FMAX
38 L Y+QR11 R0 FMAX M91
39 ;
40 PLANE SPATIAL SPA-90 SPB+0 SPC+90 TURN MB MAX FMAX SEQ- TABLE ROT
41 TCH PROBE 427 MESSEN KOORDINATE ~
Q263=-70 ;1. PUNKT 1. ACHSE ~
Q264=+0 ;1. PUNKT 2. ACHSE ~
Q261=+85 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q272=+2 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q260=+200 ;SICHERE HOEHE ~
Q281=+0 ;MESSPROTOKOLL ~
Q288=+0 ;GROESSTMASS ~
Q289=+0 ;KLEINSTMASS ~
Q309=+0 ;PGM-STOP BEI FEHLER ~
Q330=+0 ;WERKZEUG ~
Q498=+0 ;WERKZEUG UMKEHREN ~
Q531=+0 ;ANSTELLWINKEL
42 QR263 = - Q261
43 QR264 = Q263
44 Q173 = - Q160
45 PLANE RESET STAY
46 ;
47 PLANE SPATIAL SPA-90 SPB+0 SPC-90 TURN MB MAX FMAX SEQ- TABLE ROT
48 TCH PROBE 427 MESSEN KOORDINATE ~
Q263=+70 ;1. PUNKT 1. ACHSE ~
Q264=+0 ;1. PUNKT 2. ACHSE ~
Q261=+85 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q272=+2 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q260=+200 ;SICHERE HOEHE ~
Q281=+0 ;MESSPROTOKOLL ~
Q288=+0 ;GROESSTMASS ~
Q289=+0 ;KLEINSTMASS ~
Q309=+0 ;PGM-STOP BEI FEHLER ~
Q330=+0 ;WERKZEUG ~
Q498=+0 ;WERKZEUG UMKEHREN ~
Q531=+0 ;ANSTELLWINKEL
49 QR265 = Q261
50 QR266 = - Q263
51 Q174 = - Q160
52 PLANE RESET STAY
53 ;
54 PLANE SPATIAL SPA-90 SPB+0 SPC+0 TURN MB MAX FMAX SEQ- TABLE ROT
55 TCH PROBE 427 MESSEN KOORDINATE ~
Q263=+0 ;1. PUNKT 1. ACHSE ~
Q264=+0 ;1. PUNKT 2. ACHSE ~
Q261=+115 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q272=+2 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q260=+200 ;SICHERE HOEHE ~
Q281=+0 ;MESSPROTOKOLL ~
Q288=+0 ;GROESSTMASS ~
Q289=+0 ;KLEINSTMASS ~
Q309=+0 ;PGM-STOP BEI FEHLER ~
Q330=+0 ;WERKZEUG ~
Q498=+0 ;WERKZEUG UMKEHREN ~
Q531=+0 ;ANSTELLWINKEL
56 QR296 = Q263
57 QR297 = Q261
58 Q175 = - Q160
59 PLANE RESET TURN MB MAX FMAX
60 ;
61 PLANE POINTS P1X+QR263 P1Y+QR264 P1Z+Q173 P2X+QR265 P2Y+QR266 P2Z+Q174 P3X+QR296 P3Y+QR297 P3Z+Q175 STAY SEQ- TABLE ROT
62 FN 0: Q1 =+Q120
63 FN 0: Q2 =+Q122
64 PLANE RESET STAY
65 FN 0: Q120 =+Q1
66 FN 0: Q122 =+Q2
67 Q1600 = 360 - Q2
68 PLANE SPATIAL SPA+Q120 SPB+0 SPC+Q122 TURN MB MAX FMAX SEQ- TABLE ROT
69 ;*********************************************
70 ;
71 ;
72 CYCL DEF 330 Werte in Preset ~
Q1525=+1 ;löschen/schreiben
73 ;
74 CALL LBL "Schwenken"
75 CYCL DEF 10.0 DREHUNG
76 CYCL DEF 10.1 ROT+Q1600
77 TCH PROBE 412 BZPKT KREIS INNEN ~
Q321=+0 ;MITTE 1. ACHSE ~
Q322=+0 ;MITTE 2. ACHSE ~
Q262=+175 ;SOLL-DURCHMESSER ~
Q325=+0 ;STARTWINKEL ~
Q247=+90 ;WINKELSCHRITT ~
Q261=+20 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q260=+100 ;SICHERE HOEHE ~
Q301=+0 ;FAHREN AUF S. HOEHE ~
Q305=+QR2 ;NR. IN TABELLE ~
Q331=+0 ;BEZUGSPUNKT ~
Q332=+0 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE ~
Q381=+0 ;ANTASTEN TS-ACHSE ~
Q382=+0 ;1. KO. FUER TS-ACHSE ~
Q383=+0 ;2. KO. FUER TS-ACHSE ~
Q384=+0 ;3. KO. FUER TS-ACHSE ~
Q333=+0 ;BEZUGSPUNKT ~
Q423=+4 ;ANZAHL ANTASTUNGEN ~
Q365=+1 ;VERFAHRART
78 ;
79 M0
80 ;*********************************************
81 *
82 * >>> Ende <<<
83 *
84 FN 17: SYSWRITE ID 507 NRQR2 IDX1 =+0 ; X-Achse 0 setzen
85 FN 17: SYSWRITE ID 507 NRQR2 IDX2 =+0 ; Y-Achse 0 setzen
86 CYCL DEF 330 Werte in Preset ~
Q1525=+0 ;löschen/schreiben
87 FN 17: SYSWRITE ID 508 NRQR2 IDX6 =+QR100 ; C_OFFS in die aktuelle Bezugspunkttabelle einschreiben!
88 ;
89 ;*********************************************
90 CALL PGM TNC:\PROGRAMME\Abkippen-Ende.H
91 ;*********************************************
92 M30 M31
93 ;*********************************************
94 * - LBL "Schwenken"
95 LBL "Schwenken"
96 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX SEQ- TABLE ROT
97 LBL 0
98 ;*********************************************
99 END PGM UNTERSEITE_TASTEN MM
TOP    
Beitrag 12.03.2022, 07:05 Uhr
schwindl
schwindl
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 18.09.2008
Beiträge: 2.311

Hallo,

dieser Teil ist gefährlich:

62 FN 0: Q1 =+Q120
63 FN 0: Q2 =+Q122
64 PLANE RESET STAY
65 FN 0: Q120 =+Q1
66 FN 0: Q122 =+Q2
67 Q1600 = 360 - Q2
68 PLANE SPATIAL SPA+Q120 SPB+0 SPC+Q122 TURN MB MAX FMAX SEQ- TABLE ROT

Du nimmst Achswinkel und schreibst diese dann als Raumwinkel in einen Plane Satz
Besser nach dem Plane Points mit der FN18 den aktuellen 3D-Rot auslesen. Diesen kannst du dann im Plane verwenden.

Zweitens tastest du deine Punkte in unterschiedlichen Schwenkstellungen. Da wäre es besser die Punkte nicht zu messen, sondern als Bezugspunkt in die Presettabelle zu schreiben. Also jeder Punkt in eine neue Zeile. Die Punkte werden dann automatisch in das ungeschwenkte System gerechnet. Du musst sie dann nur mit FN18 auslesen und im Plane Points verwenden.

Der Beitrag wurde von schwindl bearbeitet: 12.03.2022, 07:06 Uhr


--------------------
Gruß
Schwindl
TOP    
Beitrag 12.03.2022, 09:18 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Okay, danke dir. Da werde ich es nochmal überarbeiten
TOP    
Beitrag 14.03.2022, 16:53 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Es hat funktioniert, ich hoffe noch auf ein positives Feedback. smile.gif

0 BEGIN PGM UNTERSEITE_TASTEN MM
1 FUNCTION MODE MILL
2 * - ******************************************
3 * - Unterseite antasten und gerade stellen mit Einzelne Achse tasten und Plane Points in 3_Bezugspunkttabellen!
4 * - ******************************************
5 ; - Aufbau:
6 ; - ROTA-S_flex ohne Tuerme mit harten >geschliffenen< Backen (2.Treppe)
7 ; - Kurze Grundbacken >normal< herum einschieben (6.Stufe-->8mm)
8 ; - Einstellrin Dm175x31,2
9 ; - Aufhebung der Bezugspunktsperre in den Tabellen 7/8/9 funktioniert nicht ueber QR-Parameter! Haendisch aendern!
10 ; - 10Nm
11 ; - NP mittig
12 ;
13 ;*********************************************
14 QR1 = 24 ; Bezugspunkttabelle G_2.Treppe
15 QR2 = 18 ; Bezugspunkttabelle ROTA-S_tasten
16 QR173 = 7 ; Bezugspunkttabelle Hilfe_1
17 QR174 = 8 ; Bezugspunkttabelle Hilfe_2
18 QR174 = 9 ; Bezugspunkttabelle Hilfe_3
19 ;*********************************************
20 QR10 = 0 ; Freifahren in X rechts
21 QR11 = 400 ; Freifahren in Y auf Mitte
22 QR12 = 800 ; Freifahren in Y hinten
23 FN 17: SYSWRITE ID 507 NRQR2 IDX1 =+0 ; X-Achse 0 setzen
24 FN 17: SYSWRITE ID 507 NRQR2 IDX2 =+0 ; Y-Achse 0 setzen
25 ;
26 FN 18: SYSREAD QR100 = ID508 NR15 IDX6 ; C_OFFS aus der Bezugspunkttabelle Kinematik auslesen!
27 FN 17: SYSWRITE ID 508 NRQR1 IDX6 =+QR100 ; C_OFFS in die aktuelle Bezugspunkttabelle einschreiben!
28 FN 17: SYSWRITE ID 508 NRQR2 IDX6 =+QR100 ; C_OFFS in die aktuelle Bezugspunkttabelle einschreiben!
29 ;
30 FN 18: SYSREAD QR101 = ID507 NRQR1 IDX3
31 FN 17: SYSWRITE ID 507 NRQR2 IDX3 =+QR101
32 ;
33 QS0 = "!L" ;Parameter fuer die Aufhebung definieren
34 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\7\LOCKED" = QS0 ;Gewuenschte PRESET Zeile entsperren
35 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\8\LOCKED" = QS0 ;Gewuenschte PRESET Zeile entsperren
36 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\9\LOCKED" = QS0 ;Gewuenschte PRESET Zeile entsperren
37 ;*********************************************
38 * - MESSTASTER
39 TOOL CALL "MESSTASTER" Z
40 M140 MB MAX
41 M25 M27
42 ;
43 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+QR2 ;BEZUGSPUNKT-NUMMER
44 CYCL DEF 330 Werte in Preset ~
Q1525=+0 ;löschen/schreiben
45 PLANE RESET STAY
46 L A+0 C+0 R0 FMAX
47 L Y+QR11 R0 FMAX M91
48 ;
49 PLANE SPATIAL SPA-90 SPB+0 SPC+90 TURN MB MAX FMAX SEQ- TABLE ROT
50 TCH PROBE 419 BZPKT EINZELNE ACHSE ~
Q263=-70 ;1. PUNKT 1. ACHSE ~
Q264=+0 ;1. PUNKT 2. ACHSE ~
Q261=+85 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q260=+200 ;SICHERE HOEHE ~
Q272=+2 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q305=+QR173 ;NR. IN TABELLE ~
Q333=+0 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE
51 QR263 = - Q261
52 QR264 = Q263
53 FN 18: SYSREAD Q173 = ID507 NRQR173 IDX3 ; Z-Achse aus Bezugspunktabelle auslesen
54 PLANE RESET STAY
55 ;
56 PLANE SPATIAL SPA-90 SPB+0 SPC-90 TURN MB MAX FMAX SEQ- TABLE ROT
57 TCH PROBE 419 BZPKT EINZELNE ACHSE ~
Q263=+70 ;1. PUNKT 1. ACHSE ~
Q264=+0 ;1. PUNKT 2. ACHSE ~
Q261=+85 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q260=+200 ;SICHERE HOEHE ~
Q272=+2 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q305=+QR174 ;NR. IN TABELLE ~
Q333=+0 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE
58 QR265 = Q261
59 QR266 = - Q263
60 FN 18: SYSREAD Q174 = ID507 NRQR174 IDX3 ; Z-Achse aus Bezugspunktabelle auslesen
61 PLANE RESET STAY
62 ;
63 PLANE SPATIAL SPA-90 SPB+0 SPC+0 TURN MB MAX FMAX SEQ- TABLE ROT
64 TCH PROBE 419 BZPKT EINZELNE ACHSE ~
Q263=+0 ;1. PUNKT 1. ACHSE ~
Q264=+0 ;1. PUNKT 2. ACHSE ~
Q261=+115 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q260=+200 ;SICHERE HOEHE ~
Q272=+2 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q305=+QR175 ;NR. IN TABELLE ~
Q333=+0 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE
65 QR296 = Q263
66 QR297 = Q261
67 FN 18: SYSREAD Q175 = ID507 NRQR175 IDX3 ; Z-Achse aus Bezugspunktabelle auslesen
68 PLANE RESET TURN MB MAX FMAX
69 ;
70 PLANE POINTS P1X+QR263 P1Y+QR264 P1Z+Q173 P2X+QR265 P2Y+QR266 P2Z+Q174 P3X+QR296 P3Y+QR297 P3Z+Q175 STAY SEQ- TABLE ROT
71 Q1600 = 360 - Q122
72 PLANE SPATIAL SPA+Q120 SPB+0 SPC+Q122 TURN MB MAX FMAX SEQ- TABLE ROT
73 ;*********************************************
74 ;
75 ;
76 CYCL DEF 330 Werte in Preset ~
Q1525=+1 ;löschen/schreiben
77 ;
78 CALL LBL "Schwenken"
79 CYCL DEF 10.0 DREHUNG
80 CYCL DEF 10.1 ROT+Q1600
81 TCH PROBE 412 BZPKT KREIS INNEN ~
Q321=+0 ;MITTE 1. ACHSE ~
Q322=+0 ;MITTE 2. ACHSE ~
Q262=+175 ;SOLL-DURCHMESSER ~
Q325=+0 ;STARTWINKEL ~
Q247=+90 ;WINKELSCHRITT ~
Q261=+20 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q260=+100 ;SICHERE HOEHE ~
Q301=+0 ;FAHREN AUF S. HOEHE ~
Q305=+QR2 ;NR. IN TABELLE ~
Q331=+0 ;BEZUGSPUNKT ~
Q332=+0 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE ~
Q381=+0 ;ANTASTEN TS-ACHSE ~
Q382=+0 ;1. KO. FUER TS-ACHSE ~
Q383=+0 ;2. KO. FUER TS-ACHSE ~
Q384=+0 ;3. KO. FUER TS-ACHSE ~
Q333=+0 ;BEZUGSPUNKT ~
Q423=+4 ;ANZAHL ANTASTUNGEN ~
Q365=+1 ;VERFAHRART
82 ;
83 M0
84 ;*********************************************
85 *
86 * >>> Ende <<<
87 *
88 FN 17: SYSWRITE ID 507 NRQR2 IDX1 =+0 ; X-Achse 0 setzen
89 FN 17: SYSWRITE ID 507 NRQR2 IDX2 =+0 ; Y-Achse 0 setzen
90 CYCL DEF 330 Werte in Preset ~
Q1525=+0 ;löschen/schreiben
91 FN 17: SYSWRITE ID 508 NRQR2 IDX6 =+QR100 ; C_OFFS in die aktuelle Bezugspunkttabelle einschreiben!
92 ;
93 QS0 = "L" ;Parameter fuer das Sperren (L=LOCKED) definieren
94 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\7\LOCKED" = QS0 ;Gewuenschte PRESET Zeile sperren
95 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\8\LOCKED" = QS0 ;Gewuenschte PRESET Zeile sperren
96 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\9\LOCKED" = QS0 ;Gewuenschte PRESET Zeile sperren
97 ;*********************************************
98 CALL PGM TNC:\PROGRAMME\Abkippen-Ende.H
99 ;*********************************************
100 M30 M31
101 ;*********************************************
102 * - LBL "Schwenken"
103 LBL "Schwenken"
104 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX SEQ- TABLE ROT
105 LBL 0
106 ;*********************************************
107 END PGM UNTERSEITE_TASTEN MM
TOP    
Beitrag 14.03.2022, 18:17 Uhr
schwindl
schwindl
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 18.09.2008
Beiträge: 2.311

Hallo,

bei Satz 70 PLANE POINTS P1X+QR263 P1Y+QR264 P1Z+Q173 P2X+QR265 P2Y+QR266 P2Z+Q174 P3X+QR296 P3Y+QR297 P3Z+Q175 STAY SEQ- TABLE ROT
71 Q1600 = 360 - Q122
72 PLANE SPATIAL SPA+Q120 SPB+0 SPC+Q122 TURN MB MAX FMAX SEQ- TABLE

Den 71 und 72 löschen und dafür 3D-Rot auslesen

FN 18 QR50 ID210 NR5 IDX1 ;SPA
FN 18 QR51 ID210 NR5 IDX2 ;SPB
FN 18 QR52 ID210 NR5 IDX3 ;SPC

Danach mit Plane die Werte QR50 - QR52 einschwenken

Was machst Du mir Satz 72?


--------------------
Gruß
Schwindl
TOP    
Beitrag 15.03.2022, 09:01 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Im Satz 72 schwenkt er mit den Achswinkeln in A- und C-Achse ein.

Satz 18 ist auch falsch, sehe ich gerade.

Wenn ich wieder Zeit habe, probiere ich das letztgenannte aus.
Nimmt die Steuerung, die Achsen so dann mit?
Also das 0 Grad beim neu eingeschwenkten Zustand ist.

Danke dir

Der Beitrag wurde von Smyrre bearbeitet: 15.03.2022, 09:06 Uhr
TOP    
Beitrag 16.03.2022, 22:05 Uhr
Smyrre
Smyrre
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 26.01.2012
Beiträge: 38

Danke dir herzlichst Schwindl, für deine Mühen!


0 BEGIN PGM UNTERSEITE_TASTEN MM
1 FUNCTION MODE MILL
2 * - ******************************************
3 * - Unterseite antasten und gerade stellen mit Einzelne Achse tasten und Plane Points in 3_Bezugspunkttabellen!
4 * - ******************************************
5 ; - Aufbau:
6 ; - ROTA-S_flex ohne Tuerme mit harten >geschliffenen< Backen (2.Treppe)
7 ; - Kurze Grundbacken >normal< herum einschieben (6.Stufe-->8mm)
8 ; - Einstellrin Dm175x31,2
9 ; - Aufhebung der Bezugspunktsperre in den Tabellen 7/8/9 funktioniert nicht ueber QR-Parameter! Haendisch aendern!
10 ; - 10Nm
11 ; - NP mittig
12 ;
13 ;*********************************************
14 QR1 = 24 ; Bezugspunkttabelle G_2.Treppe
15 QR2 = 18 ; Bezugspunkttabelle ROTA-S_tasten
16 QR173 = 7 ; Bezugspunkttabelle Hilfe_1
17 QR174 = 8 ; Bezugspunkttabelle Hilfe_2
18 QR175 = 9 ; Bezugspunkttabelle Hilfe_3
19 ;*********************************************
20 QR10 = 0 ; Freifahren in X rechts
21 QR11 = 400 ; Freifahren in Y auf Mitte
22 QR12 = 800 ; Freifahren in Y hinten
23 FN 17: SYSWRITE ID 507 NRQR2 IDX1 =+0 ; X-Achse 0 setzen
24 FN 17: SYSWRITE ID 507 NRQR2 IDX2 =+0 ; Y-Achse 0 setzen
25 ;
26 FN 18: SYSREAD QR100 = ID508 NR15 IDX6 ; C_OFFS aus der Bezugspunkttabelle Kinematik auslesen!
27 FN 17: SYSWRITE ID 508 NRQR1 IDX6 =+QR100 ; C_OFFS in die aktuelle Bezugspunkttabelle einschreiben!
28 FN 17: SYSWRITE ID 508 NRQR2 IDX6 =+QR100 ; C_OFFS in die aktuelle Bezugspunkttabelle einschreiben!
29 ;
30 FN 18: SYSREAD QR101 = ID507 NRQR1 IDX3
31 FN 17: SYSWRITE ID 507 NRQR2 IDX3 =+QR101
32 ;
33 QS0 = "!L" ;Parameter fuer die Aufhebung definieren
34 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\7\LOCKED" = QS0 ;Gewuenschte PRESET Zeile entsperren
35 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\8\LOCKED" = QS0 ;Gewuenschte PRESET Zeile entsperren
36 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\9\LOCKED" = QS0 ;Gewuenschte PRESET Zeile entsperren
37 ;*********************************************
38 * - MESSTASTER
39 TOOL CALL "MESSTASTER" Z
40 M140 MB MAX
41 M25 M27
42 ;
43 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+QR2 ;BEZUGSPUNKT-NUMMER
44 CYCL DEF 330 Werte in Preset ~
Q1525=+0 ;löschen/schreiben
45 PLANE RESET STAY
46 L A+0 C+0 R0 FMAX
47 L Y+QR11 R0 FMAX M91
48 ;
49 PLANE SPATIAL SPA-90 SPB+0 SPC+90 TURN MB MAX FMAX SEQ- TABLE ROT
50 TCH PROBE 419 BZPKT EINZELNE ACHSE ~
Q263=-70 ;1. PUNKT 1. ACHSE ~
Q264=+0 ;1. PUNKT 2. ACHSE ~
Q261=+85 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q260=+200 ;SICHERE HOEHE ~
Q272=+2 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q305=+QR173 ;NR. IN TABELLE ~
Q333=+0 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE
51 QR263 = - Q261
52 QR264 = Q263
53 FN 18: SYSREAD Q173 = ID507 NRQR173 IDX3 ; Z-Achse aus Bezugspunktabelle auslesen
54 PLANE RESET STAY
55 ;
56 PLANE SPATIAL SPA-90 SPB+0 SPC-90 TURN MB MAX FMAX SEQ- TABLE ROT
57 TCH PROBE 419 BZPKT EINZELNE ACHSE ~
Q263=+70 ;1. PUNKT 1. ACHSE ~
Q264=+0 ;1. PUNKT 2. ACHSE ~
Q261=+85 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q260=+200 ;SICHERE HOEHE ~
Q272=+2 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q305=+QR174 ;NR. IN TABELLE ~
Q333=+0 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE
58 QR265 = Q261
59 QR266 = - Q263
60 FN 18: SYSREAD Q174 = ID507 NRQR174 IDX3 ; Z-Achse aus Bezugspunktabelle auslesen
61 PLANE RESET STAY
62 ;
63 PLANE SPATIAL SPA-90 SPB+0 SPC+0 TURN MB MAX FMAX SEQ- TABLE ROT
64 TCH PROBE 419 BZPKT EINZELNE ACHSE ~
Q263=+0 ;1. PUNKT 1. ACHSE ~
Q264=+0 ;1. PUNKT 2. ACHSE ~
Q261=+115 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q260=+200 ;SICHERE HOEHE ~
Q272=+2 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q305=+QR175 ;NR. IN TABELLE ~
Q333=+0 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE
65 QR296 = Q263
66 QR297 = Q261
67 FN 18: SYSREAD Q175 = ID507 NRQR175 IDX3 ; Z-Achse aus Bezugspunktabelle auslesen
68 PLANE RESET TURN MB MAX FMAX
69 ;
70 PLANE POINTS P1X+QR263 P1Y+QR264 P1Z+Q173 P2X+QR265 P2Y+QR266 P2Z+Q174 P3X+QR296 P3Y+QR297 P3Z+Q175 STAY SEQ- TABLE ROT
71 ;
72 FN 18: SYSREAD QR273 = ID210 NR5 IDX1 ; SPA lesen
73 FN 18: SYSREAD QR274 = ID210 NR5 IDX2 ; SPB lesen
74 FN 18: SYSREAD QR275 = ID210 NR5 IDX3 ; SPC lesen
75 ;
76 PLANE SPATIAL SPA+QR273 SPB+QR274 SPC+QR275 TURN MB MAX FMAX SEQ- TABLE ROT
77 ;*********************************************
78 ;
79 ;
80 CYCL DEF 330 Werte in Preset ~
Q1525=+1 ;löschen/schreiben
81 ;
82 CALL LBL "Schwenken"
83 TCH PROBE 412 BZPKT KREIS INNEN ~
Q321=+0 ;MITTE 1. ACHSE ~
Q322=+0 ;MITTE 2. ACHSE ~
Q262=+175 ;SOLL-DURCHMESSER ~
Q325=+0 ;STARTWINKEL ~
Q247=+90 ;WINKELSCHRITT ~
Q261=+20 ;MESSHOEHE ~
Q320=+10 ;SICHERHEITS-ABST. ~
Q260=+100 ;SICHERE HOEHE ~
Q301=+0 ;FAHREN AUF S. HOEHE ~
Q305=+QR2 ;NR. IN TABELLE ~
Q331=+0 ;BEZUGSPUNKT ~
Q332=+0 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE ~
Q381=+0 ;ANTASTEN TS-ACHSE ~
Q382=+0 ;1. KO. FUER TS-ACHSE ~
Q383=+0 ;2. KO. FUER TS-ACHSE ~
Q384=+0 ;3. KO. FUER TS-ACHSE ~
Q333=+0 ;BEZUGSPUNKT ~
Q423=+4 ;ANZAHL ANTASTUNGEN ~
Q365=+1 ;VERFAHRART
84 ;
85 M0
86 ;*********************************************
87 *
88 * >>> Ende <<<
89 *
90 FN 17: SYSWRITE ID 507 NRQR2 IDX1 =+0 ; X-Achse 0 setzen
91 FN 17: SYSWRITE ID 507 NRQR2 IDX2 =+0 ; Y-Achse 0 setzen
92 CYCL DEF 330 Werte in Preset ~
Q1525=+0 ;löschen/schreiben
93 FN 17: SYSWRITE ID 508 NRQR2 IDX6 =+QR100 ; C_OFFS in die aktuelle Bezugspunkttabelle einschreiben!
94 ;
95 QS0 = "L" ;Parameter fuer das Sperren (L=LOCKED) definieren
96 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\7\LOCKED" = QS0 ;Gewuenschte PRESET Zeile sperren
97 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\8\LOCKED" = QS0 ;Gewuenschte PRESET Zeile sperren
98 DATA WRITE "\TABLE\'TNC:\table\preset.pr'\NO\9\LOCKED" = QS0 ;Gewuenschte PRESET Zeile sperren
99 ;*********************************************
100 CALL PGM TNC:\PROGRAMME\Abkippen-Ende.H
101 ;*********************************************
102 M30 M31
103 ;*********************************************
104 * - LBL "Schwenken"
105 LBL "Schwenken"
106 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX SEQ- TABLE ROT
107 LBL 0
108 ;*********************************************
109 END PGM UNTERSEITE_TASTEN MM
TOP    



1 Besucher lesen dieses Thema (Gäste: 1)
0 Mitglieder: