QUOTE (HSCFraeser73 @ 08.08.2017, 23:12 Uhr)
Hallo eine Frage zum Antasten,
ich habe die Oberfläche eines Werkstücks mit Hilfe der B-Achse absolut gerade ausgerichtet und diese dann mit Bezugspunkt auf
0 gesetzt. Dann habe ich ein 5-Achs NC-Programm ablaufen lassen. In diesem wird die B und C-Achse verstellt.
Nun habe ich festgestellt das zwei Bohrungen nicht an der richtigen Position sind. Diese Bohrungen wurden gefertigt indem die B und C-Achse
verstellt wurde.
Die Maschine hat eine TNC530 Steuerung.
Was ist das schiefgelaufen?
Hallo,
schiefgelaufen ist warscheinlich, dass du die B-Achse abgenullt hast, obwohl diese ein Werkzeug oder eine weitere Rundachse mitbewegt. Dies darf man nicht machen, da ansonsten die Funktionen PLANE, M128, TCPM nicht funktionieren.
Richtig machst Du das, indem Du die Fläche ausrichtest:
0 BEGIN PGM Ausrichten MM
1 BLK FORM 0.1 Z X-30 Y-30 Z-60
2 BLK FORM 0.2 X+30 Y+30 Z+0
3 ;
4 * - Taster
5 TOOL CALL "TAST" Z
6 * Grobausrichtung
7 * - Ausrichten Flaeche 1
8 TCH PROBE 431 MEASURE PLANE ~
Q263=-15 ;1ST POINT 1ST AXIS ~
Q264=-15 ;1ST POINT 2ND AXIS ~
Q294=+0 ;1ST POINT 3RD AXIS ~
Q265=+15 ;2ND PNT IN 1ST AXIS ~
Q266=-15 ;2ND PNT IN 2ND AXIS ~
Q295=+0 ;2ND PNT IN 3RD AXIS ~
Q296=+0 ;3RD PNT IN 1ST AXIS ~
Q297=+15 ;3RD PNT IN 2ND AXIS ~
Q298=+0 ;3RD PNT IN 3RD AXIS ~
Q320=+5 ;SET-UP CLEARANCE ~
Q260=+50 ;CLEARANCE HEIGHT ~
Q281=+0 ;MEASURING LOG
9 PLANE SPATIAL SPA+Q170 SPB+Q171 SPC+Q172 MOVE DIST50 FMAX
10 * - Ausrichten X-Achse 1
11 TCH PROBE 420 MEASURE ANGLE ~
Q263=-15 ;1ST POINT 1ST AXIS ~
Q264=-30 ;1ST POINT 2ND AXIS ~
Q265=+15 ;2ND PNT IN 1ST AXIS ~
Q266=-30 ;2ND PNT IN 2ND AXIS ~
Q272=+2 ;MEASURING AXIS ~
Q267=+1 ;TRAVERSE DIRECTION ~
Q261=-5 ;MEASURING HEIGHT ~
Q320=+5 ;SET-UP CLEARANCE ~
Q260=+50 ;CLEARANCE HEIGHT ~
Q301=+0 ;MOVE TO CLEARANCE ~
Q281=+0 ;MEASURING LOG
12 PLANE RELATIV SPC+Q150 MOVE DIST50 FMAX
13 ;
14 * Feinausrichtung
15 * - Ausrichten Flaeche 2
16 TCH PROBE 431 MEASURE PLANE ~
Q263=-15 ;1ST POINT 1ST AXIS ~
Q264=-15 ;1ST POINT 2ND AXIS ~
Q294=+0 ;1ST POINT 3RD AXIS ~
Q265=+15 ;2ND PNT IN 1ST AXIS ~
Q266=-15 ;2ND PNT IN 2ND AXIS ~
Q295=+0 ;2ND PNT IN 3RD AXIS ~
Q296=+0 ;3RD PNT IN 1ST AXIS ~
Q297=+15 ;3RD PNT IN 2ND AXIS ~
Q298=+0 ;3RD PNT IN 3RD AXIS ~
Q320=+5 ;SET-UP CLEARANCE ~
Q260=+50 ;CLEARANCE HEIGHT ~
Q281=+0 ;MEASURING LOG
17 PLANE RELATIV SPC+Q172 STAY
18 PLANE RELATIV SPB+Q171 STAY
19 PLANE RELATIV SPA+Q170 MOVE DIST50 FMAX
20 * - Ausrichten X-Achse 2
21 TCH PROBE 420 MEASURE ANGLE ~
Q263=-15 ;1ST POINT 1ST AXIS ~
Q264=-30 ;1ST POINT 2ND AXIS ~
Q265=+15 ;2ND PNT IN 1ST AXIS ~
Q266=-30 ;2ND PNT IN 2ND AXIS ~
Q272=+2 ;MEASURING AXIS ~
Q267=+1 ;TRAVERSE DIRECTION ~
Q261=-5 ;MEASURING HEIGHT ~
Q320=+5 ;SET-UP CLEARANCE ~
Q260=+50 ;CLEARANCE HEIGHT ~
Q301=+0 ;MOVE TO CLEARANCE ~
Q281=+0 ;MEASURING LOG
22 PLANE RELATIV SPC+Q150 MOVE DIST50 FMAX
23 ;
24 * Ausrichtung beendet
25 * - Werte auslesen
26 FN 18: SYSREAD QR170 = ID210 NR5 IDX1 ;3D-ROT SPA
27 FN 18: SYSREAD QR171 = ID210 NR5 IDX2 ;3D-ROT SPB
28 FN 18: SYSREAD QR172 = ID210 NR5 IDX3 ;3D-ROT SPC
29 * - Raumwinkel der ausgerichteten Flaeche stehen in
30 * - QR170 > SPA
31 * - QR171 > SPB
32 * - QR172 > SPC
33 ;
34 * Bezugspunkt setzen
35 * - Einschwenken auf Flaeche
36 PLANE SPATIAL SPA+QR170 SPB+QR171 SPC+QR172 MOVE DIST50 FMAX
37 * - Tasten
38 ;
39 ;
40 ;
41 END PGM Ausrichten MM
Ausrichten.h ( 2.87KB )
Anzahl der Downloads: 37Nach dem Ausrichten musst Du dann beachten, wie Du weiter in deinem 5-Achs-Programm vorgehst. Am einfachsten ist die Verwendung eines Vektoren-Programmes, da die T-Vektoren auf die geschwenkte Fläche draufgerechnet werden. Ansonsten kann man auch TCPM ... AXIS SPATIAL verwenden, dann werden die Angaben von L XYZBC auf die geschwenkte Fläche draufgerechnet.
Was nicht funktioniert ist L XYZBC mit M128.
Bei Bearbeitungsebene Schwenken musst Du mit PLANE RELATIV arbeiten, da die Fläche schon mit PLANE SPATIAL ausgerichtet wurde.
Sehr anschaulich erklärt im Webinar:
Ausrichten_Ebene.pdf ( 421.87KB )
Anzahl der Downloads: 72