512.745 aktive Mitglieder
3.247 Besucher online
Kostenfrei registrieren
Einloggen Registrieren
HEIDENHAIN Forum

Mess- und Steuerungstechnik

Kegel mit Q-Parameter programmieren, Programm für Kegel aussen und innen.

Beitrag 16.12.2019, 17:55 Uhr
JDTerra
JDTerra
Level 1 = IndustryArena-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 06.12.2003
Beiträge: 17

Hallo,

Ich habe im Forum viel Fragen gelesen über Programmierung von Geometrischen Körper zB. Elipse, Halbkugel, Kegel und änderen,
Vielleicht hilft es dem ein oder anderen ja weiter. Habe mir Q-Parameterprogramm geschrieben für Aussen- und Innen-Kegel.

Beispielprogramm:

Kontur-Daten für Kegel
Zum Auswahl sind möglich 4-Konturen. Zwei für Innen-Kegel und zwei für Aussen-Kegel.
Innen-Kegel
Q95=1 : Innen-Kegel mit Kontur oben als Kreis
Q99=1 : Innen-Kontur unten als Nut.
Q99=2 : Innen-Kontur unten als Kreis
Aussen-Kegel
Q95=2 ; Aussen-Kegel mit Kontur unten als Kreis
Q99=3 : Aussen-Kegel mit Kontur oben als Nut
Q99=4 : Aussen-Kegel mit Kontur oben als Kreis

;-------------------------------
LBL 210
CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+1 ;BEZUGSPUNKT-NUMMER
; --------------
; Kontur-Daten
FN 0: Q0 =+53 ; Kontur-Hoehe
; Kontur-Oben
; Durchmesser
FN 0: Q15 =+59.6
; Kontur-Unten
; X=Gesamte-Breite/Durchmesser
FN 0: Q6 =+8.38
; NUT im Y-Richtung
; Y=Gesamte-Laenge
FN 0: Q7 =+23.8
; NPV-X
FN 0: Q66 =-10
; NPV-Y
FN 0: Q77 =+10
LBL 0
; ----------------------------



Werkzeug-Daten und Kontur auswahl
; ----------------------------
BLK FORM 0.1 Z X-30 Y-30 Z-60
BLK FORM 0.2 X+30 Y+30 Z+0
; ----------------------------
* - TOOL3305 VHM-To.Fr-5
TOOL CALL 3305 Z DR+0
; ----------------
FN 0: Q80 =+60 ; Vc
FN 0: Q81 =+0.08 ; f/Z
CALL PGM TNC:\ZYKLEN\-SDA
; --------------------------
FN 0: Q1 =+Q0 ; Fraes-Tiefe
FN 0: Q11 =+2 ; Start-Tiefe
FN 0: Q21 =+2 ; Zustellung
;
L M3 M13
L M110
; Q95=1 -> Q99=1 oder Q99=2
; Q95=2 -> Q99=3 oder Q99=4
FN 0: Q95 =+1 ; 1-Innen/2-Aussen
FN 0: Q99 =+2 ; LBL-Kontur
;
CALL LBL 210 ; Kontur-Daten
CALL LBL 220 ; 3D-Kontur Berechnung
;
CALL LBL 100 ; Abzeilen
L M111
;
L M9
;
CALL LBL 99
* - --- Programm-Ende ---------
L M30
* - --------------------------



3D-Kontur Beschreibung-Berechnung
; ---------------------------
LBL 220
* - LBL220 3D-Kontur Beschreibung-Berechnung
CALL LBL 260 ; Unterschnit-Kontrolle
FN 11: IF +Q0 GT +Q1 GOTO LBL 221
FN 0: Q1 =+Q0
LBL 221
X-, Y-Anfahrtwert ausrechnen
Q80 = Q15 / 2
Q16 = Q80 + Q108 + 2
Q17 = Q80
; X =Breite
Q360 = Q6 / 2
Q80 = ( Q15 - Q6 ) / 2
Q260 = Q80 / Q0
; Y =Laenge
Q80 = ( Q7 - Q6 ) / 2
Q270 = Q80 / Q0
; NPV-X,Y
Q266 = Q66 / Q0
Q277 = Q77 / Q0
LBL 0
; ----------------------------


Kontur mit LBL 100 Abzeilen im "ap"-Richtung
LBL 100 als feste CNC-Programmteil für "ap"-Abzeilen für Planflächen und Konturen.
Der LBL 100 Unterprogramm wird nie geändert.
Ausnahme: Wenn die Z+0 Werkstückfläche nicht die höchste Fläche ist, dann "L Z+50 R0 FMAX" Sicherheitsabstand auf "Z+???" über die höchste Werkstückfläche programmieren.
;-------------------------------
LBL 100
* - LBL100 Abzeilen
FN 0: Q31 =+Q11
FN 11: IF +Q31 GT +Q1 GOTO LBL 121
FN 9: IF +Q31 EQU +Q1 GOTO LBL 121
LBL 101
; ------
CALL LBL 50 ; UPGM-AUFRUF
; ------
FN 1: Q31 =+Q31 + +Q21
FN 12: IF +Q31 LT +Q1 GOTO LBL 101
LBL 121
FN 0: Q31 =+Q1
CALL LBL 101 REP1
L Z+50 R0 FMAX
LBL 0
LBL 50 ; UPGM-AUFRUF
FN 9: IF +1 EQU +1 GOTO LBL Q99
;-------------------------------



Kontur-Beschreibung für Kegel.
- Q95=1 - Innen-Kegel mit Kontur oben als Kreis.
- Q99=2 - Innen-Kontur unten als Kreis.

; ----------------------------
LBL 2
* - LBL2 Kontur_Unten = Kreis
CALL LBL 230 ; Kontur für aktuelle Tiefe
CALL LBL 151 ; NPV
;
L X+0 Y+0 R0 FMAX M3
L Z-Q31 R0 FMAX
L X+Q60 Y+0 RL FQ3
CC X+0 Y+0
CP IPA+360 DR+ FQ3
L X+0 Y+0 R0 FMAX
LBL 0
* - ; ----------------------



Kontur-Berechnung für aktuelle Tiefe
; ----------------------------
LBL 230
* - LBL230 Konturberechnung fuer aktuelle Tiefe
FN 9: IF +Q95 EQU +2 GOTO LBL 231
Q81 = Q0 - Q31
Q82 = Q31
FN 9: IF +1 EQU +1 GOTO LBL 232
LBL 231
Q82 = Q0 - Q31
Q81 = Q31
LBL 232
Q60 = ( Q81 * Q260 ) + Q360
Q70 = Q82 * Q270
Q366 = Q266 * Q82
Q377 = Q277 * Q82
LBL 0
; ----------------------------


NPV - Nullpunktverschiebung
;-------------------------------
LBL 150
; Koordinaten-Transformation zuruecksetzen
CYCL DEF 8.0 SPIEGELUNG
CYCL DEF 8.1
CYCL DEF 10.0 DREHUNG
CYCL DEF 10.1 ROT+0
CYCL DEF 7.0 NULLPUNKT
CYCL DEF 7.1 X+0
CYCL DEF 7.2 Y+0
LBL 0
;
LBL 151
CALL LBL 150
CYCL DEF 7.0 NULLPUNKT
CYCL DEF 7.1 X+Q366
CYCL DEF 7.2 Y+Q377
LBL 0
; -----------------------------


Download:
Beschreibung für Kegel Parameter-Programm
Angehängte Datei  Kegel_NPV_1.doc ( 31.5KB ) Anzahl der Downloads: 19


Beispiel Programm für Kegel
Angehängte Datei  Kegel_NPV_1.h ( 6.21KB ) Anzahl der Downloads: 9




Warum sind die Programme so aufgebaut?
Bei meine Firma haben wir Einzeln- und Kleinserienproduktion. Programmlaufzeiten 15 min bis 3 Std. Wir erstellen unsere CNC-Programme ohne CAD-Unterstützung selber direkt auf die Maschine.
Wir arbeiten im Zweischichtbetrieb auf alle Maschinnen (aktuell TNC 530 und TNC 640) mit eigenen oder von Kollegen geschriebenen Programmen.
Um effizient zu arbeiten sind die Programme nach festen Muster aufgebaut so das jede Mitarbeiter arbeitet (optimmiert, korrigiert) mit die Programme wie mit seine eigene Programm.
Neue Programm-Änderungen oder -Verbesserungen werden nach Absprache im neuen Programmen angewendet. (Die Bewertungsgrunde: Qualität-, Sicherheits-, Effizient-Verbessern)

TOP    
Beitrag 16.12.2019, 18:20 Uhr
farmer 70
farmer 70
Level 6 = IndustryArena-Doktor
******
Gruppe: Mitglied
Mitglied seit: 05.06.2005
Beiträge: 845

Hast du vielleicht noch ein paar Beispielbilder zum besseren Verständnis für deine Parameterprogramme?


--------------------
Gruß farmer



Hilfsbereitschaft, Gemeinsinn, Miteinander und Füreinander
TOP    



1 Besucher lesen dieses Thema (Gäste: 1)
0 Mitglieder: