584.850 aktive Mitglieder*
4.499 Besucher online*
Kostenfrei registrieren
Anmelden Registrieren
HEIDENHAIN Forum

Radius abzeilen

Beitrag 03.11.2011, 17:32 Uhr
Tim18
Tim18
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 21.05.2010
Beiträge: 48

Hallo zusammen!

Ich arbeite in unserem Betrieb auf einer Hermle mit Tnc 410 Steuerung und einer DMC 1035 V mit iTnc 530 Steuerung.
Jetzt habe ich ne frage und zwar kann man ja mit den Zyklen zum abzeilen eine Fläche oder Fase abzeilen.
Ich würde gern wissen ob es möglich wäre einen Radius abzuzeilen?
Habe eine Platte zu fräsen auf die auf der seite ein Radius 20 gefräst werden soll ich könnte das ganze schon mit nem Viertelkreisfräser machen
allerdings müssten wir den extra fertigen lassen weils den in der größe nicht zu bestellen gibt und die Platten sollten sowieso schon am Montag fertig sein sollten.

Danke für eure Hilfe schon im vorraus

Lg Tim
TOP    
Beitrag 03.11.2011, 19:14 Uhr
cncfutzi
cncfutzi
Level 3 = Community-Techniker
***
Gruppe: Mitglied
Mitglied seit: 30.05.2006
Beiträge: 241

QUOTE (Tim18 @ 03.11.2011, 18:32 Uhr) *
Hallo zusammen!

Ich arbeite in unserem Betrieb auf einer Hermle mit Tnc 410 Steuerung und einer DMC 1035 V mit iTnc 530 Steuerung.
Jetzt habe ich ne frage und zwar kann man ja mit den Zyklen zum abzeilen eine Fläche oder Fase abzeilen.
Ich würde gern wissen ob es möglich wäre einen Radius abzuzeilen?
Habe eine Platte zu fräsen auf die auf der seite ein Radius 20 gefräst werden soll ich könnte das ganze schon mit nem Viertelkreisfräser machen
allerdings müssten wir den extra fertigen lassen weils den in der größe nicht zu bestellen gibt und die Platten sollten sowieso schon am Montag fertig sein sollten.

Danke für eure Hilfe schon im vorraus

Lg Tim


Hallo
Auf die schnelle und ohne viel aufwand .
Wenn es in einer Achse ist
Kontur im Unterprogramm mit L IX0.5 oder so
Unterprogramm und 99999 wiederholungen .
gruss
cncfutzi
TOP    
Beitrag 03.11.2011, 22:50 Uhr
Tim18
Tim18
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 21.05.2010
Beiträge: 48

Ok aber ich muss doch auch inkremental in der Z achse verfahren oder?
TOP    
Beitrag 04.11.2011, 00:39 Uhr
schwindl
schwindl
Level 7 = Community-Professor
*******
Gruppe: Mitglied
Mitglied seit: 18.09.2008
Beiträge: 2.311

Hallo Tim, wie willst du denn deinen Radius abzeilen? Mit Kugelfraser oder schaftfraeser? Schau doch mal auf heidenhain.de unter Service und dokumentatioq da gibst die nc Datenbank,da findest ein pgm tust dich


--------------------
Gruß
Schwindl
TOP    
Beitrag 04.11.2011, 11:58 Uhr
Tim18
Tim18
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 21.05.2010
Beiträge: 48

Hallo Schwindl,

Danke für deine antwort erstmal, wollt dich fragen ob du eventuell ein link von dem PGM hier posten könntest weil ich habe schon nachgeschaut und aber kein passendes PGM gefunden.

Gruß Tim
TOP    
Beitrag 04.11.2011, 13:47 Uhr
Tim18
Tim18
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 21.05.2010
Beiträge: 48

Hier ist ne Zeichnung.
Ich würde die Platte flach spannen dann die erste seite abzeilen dann umdrehen und dann die andere seite weil um sie hoch zu spannen ist sie ein bisschen zu groß.
Angehängte Datei(en)
Angehängte Datei  Mageba_Tensa.PNG ( 30.28KB ) Anzahl der Downloads: 486
 
TOP    
Beitrag 04.11.2011, 16:35 Uhr
WarFish
WarFish
Level 4 = Community-Meister
****
Gruppe: Mitglied
Mitglied seit: 24.06.2005
Beiträge: 478

Hallo!

Ich hab ein Programm für dich mit dem das geht, ich nutze es auch des öfteren.

Ausgelegt ist es für torische Fräser. Wenn du den Winkelschritt kleiner wählst wird die Oberfläche schöner ,
aber die Bearbeitung dauert entsprechend länger. Die Kontur an der du entlang fräsen willst, definierst du im LBL10 am Ende des Programms.

Sollte aber soweit selbsterklärend sein, kannst es ja mal ausprobieren.

Ich will mich aber auch nicht mit fremden Federn schmücken, dies Programm ist nicht von mir. Entweder hab ich´s von hier oder aus der schon erwähnten Datenbank von Heidenhain.


0 BEGIN PGM RADIUSANKONTUR MM
1 BLK FORM 0.1 Z X-50 Y-50 Z-20
2 BLK FORM 0.2 X+50 Y+50 Z+0
3 L Z+150 R0 F MAX
4 FN 0: Q1 = +8 ; RADIUS AN DER KONTUR
5 FN 0: Q2 = +0 ; STARTWINKEL
6 FN 0: Q3 = +1 ; ECKENRADIUS FRAESER
7 FN 0: Q4 = +90 ; ENDWINKEL
8 FN 0: Q5 = +4 ; WINKELSCHRITT
9 FN 1: Q10 = +Q2 + -Q5
10 LBL 1
11 FN 1: Q10 = +Q10 + +Q5
12 Q11 = (Q1 + Q3) * (1 - SIN Q10)
13 Q12 = (Q1 + Q3) * (1 - COS Q10)
14 TOOL CALL 13 Z S5500 DL-Q12 DR-Q11 ; TORUS 12 R1
15 CALL LBL 10
16 FN 12: IF +Q10 LT +Q4 GOTO LBL 2
17 FN 0: Q10 = +Q4
18 LBL 2
19 FN 12: IF +Q10 LT +Q4 GOTO LBL 1
20 L Z+150 R0 F MAX
21 L Y+630 R0 F MAX M91 M30
22 LBL 10 ; X-BELIEBIGE KONTUR
23 L X-60 Y-60 R0 F MAX
24 L Z+0 R0 F MAX M3
25 L X-50 RL F3000
26 L Y+50
27 L X+50
28 L Y-50
29 L X-60
30 L Y-60 R0
31 LBL 0
32 END PGM RADIUSANKONTUR MM


Gruß, Stefan..


--------------------
Let there be rock!
TOP    
Beitrag 06.11.2011, 17:24 Uhr
teerz
teerz
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 08.12.2010
Beiträge: 2

Hallo Tim18

hier ist meine Variante.

0 BEGIN PGM Aussenradius variabel MM
1 BLK FORM 0.1 Z X-20 Y+0 Z-50
2 BLK FORM 0.2 X+20 Y+50 Z+0
3 * - Aussenradius
4 * - fuer BNF-TORUS-KUGELFRAESER
5 TOOL CALL 11 Z S5000 F1000
6 FN 0: Q500 =+90 ;ENDWINKEL
7 FN 0: Q501 =+45 ;SCHRITTE
8 Q510 = Q500 / Q501 ;ZUSTELLUNG
9 FN 0: Q502 =+20 ;RADIUS
10 FN 0: Q503 =+0 ;AUFMASS
11 FN 0: Q504 =+0 ;STARTWINKEL
12 CYCL DEF 14.0 KONTUR
13 CYCL DEF 14.1 KONTURLABEL1
14 L X+0 Y+0 Z+30 R0 FMAX M13
15 LBL 11
16 FN 18: SYSREAD Q505 = ID50 NR3
17 Q506 = ( ( ( SIN Q504 * ( Q505 + Q502 ) ) - Q502 ) + Q503 - Q505 )
18 Q507 = ( COS Q504 * ( Q505 + Q502 ) - Q505 )
19 CYCL DEF 7.0 NULLPUNKT
20 CYCL DEF 7.1 Z+Q507
21 CYCL DEF 25 KONTUR-ZUG ~
Q1=-Q502 ;FRAESTIEFE ~
Q3=+Q506 ;AUFMASS SEITE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q7=+20 ;SICHERE HOEHE ~
Q10=-20 ;ZUSTELL-TIEFE ~
Q11= AUTO ;VORSCHUB TIEFENZ. ~
Q12= AUTO ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART
22 CYCL DEF 270 KONTURZUG-DATEN ~
Q390=+2 ;ANFAHRART ~
Q391=+1 ;RADIUS-KORREKTUR ~
Q392=+5 ;RADIUS ~
Q393=+90 ;MITTELPUNKTSWINKEL ~
Q394=+5 ;ABSTAND
23 M99
24 CYCL DEF 7.0 NULLPUNKT
25 CYCL DEF 7.1 Z+0
26 Q504 = Q504 + Q510
27 CALL LBL 11 REPQ501
28 L Z-10 R0 FMAX M91
29 M30
30 LBL 1
31 * - Kontur LBL1
32 L X+20 Y+0 RL
33 L X-20
34 LBL 0
35 END PGM Aussenradius variabel MM
TOP    
Beitrag 07.11.2011, 20:23 Uhr
Tim18
Tim18
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 21.05.2010
Beiträge: 48

Danke leute für eure Hilfe hat perfekt funktioniert :-))

Gruß Tim
TOP    
Beitrag 07.11.2011, 20:39 Uhr
Bender {MMO}
Bender {MMO}
Level 4 = Community-Meister
****
Gruppe: Mitglied
Mitglied seit: 13.01.2006
Beiträge: 313

Hallo Tim,

darf ich fragen wie du es gemacht hast? Hat ja hier mehrere Vorschläge gegeben...
TOP    
Beitrag 10.11.2011, 22:02 Uhr
Tim18
Tim18
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 21.05.2010
Beiträge: 48

Ich hab das Pgm von Warfish verwendet smile.gif
TOP    
Beitrag 23.01.2012, 12:20 Uhr
micehm
micehm
Level 2 = Community-Facharbeiter
**
Gruppe: Mitglied
Mitglied seit: 08.07.2004
Beiträge: 101

Hallo,

das Thema ist zwar schon einige Monate alt, doch ich muss es noch einmal hoch holen. Das Programm hat mir schon gut weiter geholfen.

Die Frage ist, hat jemand vielleicht auch schon so ein Programm für einen größeren Fußradius zum Beispiel einen R12 in einem Taschengrund. Oder ist es denkbar das normale Radiusprogramm um Z zu Spiegeln?

Danke!
TOP    
Beitrag 25.02.2021, 20:47 Uhr
Dogmar
Dogmar
Level 1 = Community-Lehrling
*
Gruppe: Mitglied
Mitglied seit: 07.02.2015
Beiträge: 20

Kann man so vieleicht auch mein Problem Lösen?
https://de.industryarena.com/forum/index.ph...st&id=24273

Der Beitrag wurde von Dogmar bearbeitet: 25.02.2021, 20:49 Uhr
TOP    



1 Besucher lesen dieses Thema (Gäste: 1)
0 Mitglieder: