TNC Schwenkübung macht Sorgen, 5 Achs schwenken nach Musterlösung

Hallo liebe Gemeinde,

ich habe bei Youtube ein Übungsteil zum Schwenken gefunden, komme aber nicht darauf ,warum für das ausführen des LBL4 ,
die SPA Achse um SPA+40.893 geschwenkt wird. Wie kommt man auf den Wert ? Könnte mir das jemand erklären ?
Ich komme da einfach nicht drauf.....
Vielen Dank schon mal

https://www.youtube.com/watch?v=xv5pSYnY6lA


Führung 20 mm breit 10 tief mit einer 20x45° Fase und einer 60° Öffnung.

0 BEGIN PGM TEST MM
1 BLK FORM 0.1 Z X-25 Y-50 Z-50
2 BLK FORM 0.2 X+25 Y+0 Z+0
3 TOOL CALL 1 Z S4000 F800
4 CYCL DEF 14.0 KONTUR
5 CYCL DEF 14.1 KONTURLABEL1
6 CYCL DEF 25 KONTUR-ZUG ~
Q1=-10 ;FRAESTIEFE ~
Q3=+0 ;AUFMASS SEITE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q7=+2 ;SICHERE HOEHE ~
Q10=-5 ;ZUSTELL-TIEFE ~
Q11=+2000 ;VORSCHUB TIEFENZ. ~
Q12= AUTO ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART
7 CYCL CALL M13
8 CYCL DEF 7.0 NULLPUNKT
9 CYCL DEF 7.1 X+0
10 CYCL DEF 7.2 Y-30
11 CYCL DEF 7.3 Z-10
12 PLANE SPATIAL SPA+45 SPB+0 SPC+0 TURN MB150 FMAX
13 CYCL DEF 14.0 KONTUR
14 CYCL DEF 14.1 KONTURLABEL2
15 CYCL DEF 25 KONTUR-ZUG ~
Q1=-14.14 ;FRAESTIEFE ~
Q3=+0 ;AUFMASS SEITE ~
Q5=+14.14 ;KOOR. OBERFLAECHE ~
Q7=+16 ;SICHERE HOEHE ~
Q10=-5 ;ZUSTELL-TIEFE ~
Q11=+2000 ;VORSCHUB TIEFENZ. ~
Q12= AUTO ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART
16 CYCL CALL
17 CYCL DEF 14.0 KONTUR
18 CYCL DEF 14.1 KONTURLABEL3
19 CYCL DEF 25 KONTUR-ZUG ~
Q1=-21 ;FRAESTIEFE ~
Q3=+0 ;AUFMASS SEITE ~
Q5=+21 ;KOOR. OBERFLAECHE ~
Q7=+23 ;SICHERE HOEHE ~
Q10=-5 ;ZUSTELL-TIEFE ~
Q11=+2000 ;VORSCHUB TIEFENZ. ~
Q12= AUTO ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART
20 CYCL CALL
21 PLANE RESET STAY
22 CYCL DEF 7.0 NULLPUNKT
23 CYCL DEF 7.1 X+10
24 CYCL DEF 7.2 Y-30
25 CYCL DEF 7.3 Z-10
26 PLANE SPATIAL SPA+40.893 SPB+0 SPC+30 TURN MB150 FMAX
27 CYCL DEF 14.0 KONTUR
28 CYCL DEF 14.1 KONTURLABEL4
29 CYCL DEF 25 KONTUR-ZUG ~
Q1=-21 ;FRAESTIEFE ~
Q3=+0 ;AUFMASS SEITE ~
Q5=+21 ;KOOR. OBERFLAECHE ~
Q7=+23 ;SICHERE HOEHE ~
Q10=-5 ;ZUSTELL-TIEFE ~
Q11=+2000 ;VORSCHUB TIEFENZ. ~
Q12= AUTO ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART
30 CYCL CALL
31 PLANE RESET STAY
32 CYCL DEF 7.0 NULLPUNKT
33 CYCL DEF 7.1 X-10
34 CYCL DEF 7.2 Y-30
35 CYCL DEF 7.3 Z-10
36 PLANE SPATIAL SPA+40.893 SPB+0 SPC-30 TURN MB150 FMAX
37 CYCL DEF 14.0 KONTUR
38 CYCL DEF 14.1 KONTURLABEL5
39 CYCL DEF 25 KONTUR-ZUG ~
Q1=-21 ;FRAESTIEFE ~
Q3=+0 ;AUFMASS SEITE ~
Q5=+21 ;KOOR. OBERFLAECHE ~
Q7=+23 ;SICHERE HOEHE ~
Q10=-5 ;ZUSTELL-TIEFE ~
Q11=+2000 ;VORSCHUB TIEFENZ. ~
Q12= AUTO ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART
40 CYCL CALL
41 PLANE RESET TURN MB150 FMAX
42 CYCL DEF 7.0 NULLPUNKT
43 CYCL DEF 7.1 X+0
44 CYCL DEF 7.2 Y+0
45 CYCL DEF 7.3 Z+0
46 L Z+150 R0 FMAX
47 L Y+150 FMAX M30
48 LBL 1
49 APPR LT X+10 Y-50 LEN8 RL
50 L Y+7 M98
51 L X-10
52 L Y-50
53 DEP LT LEN1
54 LBL 0
55 LBL 2
56 APPR LT X+10 Y-28.284 LEN8 RL
57 L Y+7
58 L IX-20
59 L Y-28.5
60 DEP LT LEN1
61 LBL 0
62 LBL 3
63 APPR LT X+21.547 Y-28.284 LEN8 RL
64 L Y+0 X+10
65 FCT X-10 Y+0 DR+
66 L X-21.547 Y-28.284
67 DEP LT LEN1
68 LBL 0
69 LBL 4
70 APPR LT X+0 Y-30.55 LEN8 RL
71 L Y+0
72 DEP LT LEN8
73 LBL 0
74 LBL 5
75 APPR LT X+0 Y+0 LEN10 RL
76 L Y-30.55
77 DEP LT LEN1
78 LBL 0
79 END PGM TEST MM

Moin!

Das ergibt sich geometrisch durch die C-Drehung um 30°. Wenn Du deine 45° Schräge hast und dann um 30 verdrehst, dennoch an der Kante unten bleiben willst mit der nächsten Kontur muss der Bearbeitungswinkel etwas steiler werden.

Du kannst ja des Spasses halber das Selbe einfach mal anstatt mit den 40,893° auf 45° abfahren und das Ergebnis anschauen.

Grüße

Moin, danke schon mal für die Antwort.
Kannst Du mir einen Rechenweg aufzeigen wie ich den Wert errechne ? Ich komme da nicht drauf wie ?
Da stehe ich irgendwie auf dem Schlauch ......

Hallo,

man kann sich das Schritt für Schritt über die Dreiecke berechnen.

 Aufnahme45.jpg ( 63.72KB ) Anzahl der Downloads: 68
 Aufnahme44.jpg ( 48.36KB ) Anzahl der Downloads: 59

Schritt 1:
 1.jpg ( 21.67KB ) Anzahl der Downloads: 45

Ergebnis 11,54701

Schritt 2:
 2.jpg ( 35.81KB ) Anzahl der Downloads: 34

Ergebnis 28,28427

Schritt 3:
 3.jpg ( 35.85KB ) Anzahl der Downloads: 28

Aus Schritt 1 und Schritt 2 wird die Hypothenuse berechnet. Ergebnis 30,55050

Schritt 4:
 4.jpg ( 54KB ) Anzahl der Downloads: 36

Aus der Hypothenuse von Schritt 3 und Gegenkathete 20 errechnet sich der Winkel 40,8934°

Der Beitrag wurde von schwindl bearbeitet: 18.10.2018, 14:59 Uhr

 TNC640__340595_.png ( 112.68KB ) Anzahl der Downloads: 77

Klasse,danke ,super erklärt.
Jetzt habe ich es endlich begriffen :-)

Moin, wir haben in unserer Firma auch immer Winkel in Winkel wodurch ein extra Winkel entsteht. Die Anleitung ist echt super. Aber dennoch, wenn ich das alles so anwende habe ich immer noch einen Absatz auf der Winkelfläche in Z.

Die obere Zeichnungsansicht ist sozusagen meine Z-Ansicht. Mein 3. Winkel wäre 9,97598 gewesen. Trotzdem frage ich mich, warum habe ich trotzdem einen spürbaren Absatz in der Z-Fläche. Habe ich was falsch gemacht oder nicht beachtet?

Der Beitrag wurde von Gizer bearbeitet: 12.04.2024, 16:42 Uhr

Nö. Wenn ich die Zeichnung richtig deute dann sind es 8° nach unten und 10° Öffnung zur Seite.

Außerdem läßt sich die Berechnung vereinfachen, ich mache mal anderes Bild:
 a.PNG ( 91.93KB ) Anzahl der Downloads: 20


Zuerst berechnen wir die rote Strecke in der Mitte der Schräge nach unten mit 8°
Dann berechnen wir die blaue Strecke an der Seitenfläche mit 10°
Diese beiden Strecken / Dreiecke könnten wir jetzt in die Ecke projizieren und daraus den Winkel berechnen.

Ein Excel o.ä. sollte auch jeder haben, ich rechne mal Deinen Fall und den obigen um zu zeigen das der richtige Wert rauskommt:
 b.PNG ( 4.11KB ) Anzahl der Downloads: 14

 c.PNG ( 4.07KB ) Anzahl der Downloads: 10


C1: =A1*TAN(BOGENMASS(B1))
C2: =A2/COS(BOGENMASS(B2))
C3: =GRAD(ARCTAN(C1/C2))

In Deinem Fall also 7,88°

Kann man auch in der Steuerung berechnen, ungetestet aber ich denke das geht.
Die Länge der Schräge ist für die Winkel unerheblich, daher kann man das als 1 annehmen.

* - PARAMETER
Q10=8 ;Winkel nach unten
Q11=10 ;Winkel zur Seite
Q12=1*TAN(Q10) ;Rote Strecke
Q13=1/COS(Q11) ;Blaue Strecke
Q14=ATAN(Q12/Q13) ;Kippwinkel

* - SCHRAEGE FRAESEN
PLANE SPATIAL SPA+Q10 SPB+0 SPC-0 TURN FMAX SEQ- TABLE ROT

* - OEFFNUNG LINKS FRAESEN
PLANE SPATIAL SPA+Q14 SPB+0 SPC-Q11 TURN FMAX SEQ- TABLE ROT

* - OEFFNUNG RECHTS FRAESEN
PLANE SPATIAL SPA+Q14 SPB+0 SPC+Q11 TURN FMAX SEQ- TABLE ROT

Alles klar?

Andreas.

Der Beitrag wurde von Andreas1964 bearbeitet: 17.04.2024, 09:02 Uhr

Die Erklärung verdeutlich nochmal alles. Danke dafür. Auf der Maschine umgesetzt. Rechnung stimmt. Vielen Dank.