Verständnisfrage zu FN 9

Guten Tag zusammen.

Ich beschäftige mich zum ersten mal mit Programmsprüngen. Schau mir gerade das Drilling Beispielprogramm vom Heidenhain Übungsplatz iTNC530 an.
Den Sprung nach allen Abarbeitungen "FN 9: IF +0 EQU +0 GOTO LBL 99" verstehe ich noch nicht ganz. Heißt ja "wenn 0 gleich 0 Spring zu LBL 99.
Auf welche Null bezieht sich der Sprung, bzw. welche Null ist denn gemeint, und LBL99 steht am Ende des Programms. Hat LBL 99 eine spezielle Bedeutung? LBL`s sollten ja eigentlich mit LBL 0 geschlossen werden.

Wäre dankbar für eine Erklärung

0 BEGIN PGM drilling MM
1 BLK FORM 0.1 Z X+0 Y+0 Z-20
2 BLK FORM 0.2 X+100 Y+100 Z+0
3 FN 0: Q1 =+2
4 TOOL CALL 4 Z S3200
5 ; D8,0
6 L Z+100 R0 FMAX M3
7 CYCL DEF 200 BOHREN ~
Q200=+2 ;SICHERHEITS-ABST. ~
Q201=-3 ;TIEFE ~
Q206=+250 ;VORSCHUB TIEFENZ. ~
Q202=+3 ;ZUSTELL-TIEFE ~
Q210=+0 ;VERWEILZEIT OBEN ~
Q203=+0 ;KOOR. OBERFLAECHE ~
Q204=+Q1 ;2. SICHERHEITS-ABST. ~
Q211=+0 ;VERWEILZEIT UNTEN
8 CALL LBL 10
9 TOOL CALL 2 Z S3800
10 ; D5,0
11 L Z+100 R0 FMAX M3
12 CYCL DEF 200 BOHREN ~
Q200=+2 ;SICHERHEITS-ABST. ~
Q201=-13 ;TIEFE ~
Q206=+350 ;VORSCHUB TIEFENZ. ~
Q202=+13 ;ZUSTELL-TIEFE ~
Q210=+0 ;VERWEILZEIT OBEN ~
Q203=+0 ;KOOR. OBERFLAECHE ~
Q204=+Q1 ;2. SICHERHEITS-ABST. ~
Q211=+0 ;VERWEILZEIT UNTEN
13 CALL LBL 10
14 TOOL CALL 3 Z S260
15 ; M6
16 L Z+100 R0 FMAX M3
17 CYCL DEF 206 GEWINDEBOHREN ~
Q200=+3 ;SICHERHEITS-ABST. ~
Q201=-8 ;GEWINDETIEFE ~
Q206=+260 ;VORSCHUB TIEFENZ. ~
Q211=+0 ;VERWEILZEIT UNTEN ~
Q203=+0 ;KOOR. OBERFLAECHE ~
Q204=+Q1 ;2. SICHERHEITS-ABST.
18 CALL LBL 10
19 L Z+100 R0 FMAX
20 FN 9: IF +0 EQU +0 GOTO LBL 99
21 LBL 1
22 CYCL DEF 220 MUSTER KREIS ~
Q216=+0 ;MITTE 1. ACHSE ~
Q217=+0 ;MITTE 2. ACHSE ~
Q244=+20 ;TEILKREIS-DURCHM. ~
Q245=+0 ;STARTWINKEL ~
Q246=+360 ;ENDWINKEL ~
Q247=+0 ;WINKELSCHRITT ~
Q241=+4 ;ANZAHL BEARBEITUNGEN ~
Q200=+Q1 ;SICHERHEITS-ABST. ~
Q203=+0 ;KOOR. OBERFLAECHE ~
Q204=+Q1 ;2. SICHERHEITS-ABST. ~
Q301=+1 ;FAHREN AUF S. HOEHE ~
Q365=+0 ;VERFAHRART
23 CYCL DEF 220 MUSTER KREIS ~
Q216=+0 ;MITTE 1. ACHSE ~
Q217=+0 ;MITTE 2. ACHSE ~
Q244=+36 ;TEILKREIS-DURCHM. ~
Q245=+0 ;STARTWINKEL ~
Q246=+360 ;ENDWINKEL ~
Q247=+0 ;WINKELSCHRITT ~
Q241=+8 ;ANZAHL BEARBEITUNGEN ~
Q200=+Q1 ;SICHERHEITS-ABST. ~
Q203=+0 ;KOOR. OBERFLAECHE ~
Q204=+Q1 ;2. SICHERHEITS-ABST. ~
Q301=+1 ;FAHREN AUF S. HOEHE ~
Q365=+0 ;VERFAHRART
24 LBL 0
25 LBL 10
26 CYCL DEF 7.0 NULLPUNKT
27 CYCL DEF 7.1 X+25
28 CYCL DEF 7.2 Y+25
29 CALL LBL 1
30 CYCL DEF 7.0 NULLPUNKT
31 CYCL DEF 7.1 Y+75
32 CALL LBL 1
33 CYCL DEF 7.0 NULLPUNKT
34 CYCL DEF 7.1 X+75
35 CALL LBL 1
36 CYCL DEF 7.0 NULLPUNKT
37 CYCL DEF 7.1 Y+25
38 CALL LBL 1
39 CYCL DEF 7.0 NULLPUNKT
40 CYCL DEF 7.1 X+0
41 CYCL DEF 7.2 Y+0
42 LBL 0
43 LBL 99
44 END PGM drilling MM

Servus,

bei FN9 bis FN12 kanst du immer 2 Werte miteinander vergleichen, du vergleichst also den ersten Wert z.B 0 mit deinen zweiten Wert in deinem Fall ebenfalls 0 und erreichst dadurch einen unbedingten Sprung zu deinen angegeben LBL. Das kann mach auch mit Q-Parameter machen
z.B" FN 9: IF +Q1 EQU +5 GOTO LBL 99", wenn dein Q1 den Wert 5 entspricht springt die Steuerung ins LBL 99 wenn die Bedingung nicht erfüllt ist überliest die Steuerung die Zeile einfach.

Servus Karlsblock.

Danke für die Antwort. Versteh leider die erste Null noch nicht. Auf was bezieht die sich, da wird ja nichts grechnet?

"Danke für die Antwort."


Ja das da hast du Recht, man will aber in den Programm erreichen dass er immer ins LBL 99 springt, eine weiter Möglichkeit wäre auch einfach
ein LBL Call 99 zu schreiben. Da das Bohrprogramm ein Programm ist das wahrscheinlich mit Zyklus 12 PGM CALL aufgerufen wird darf kein M30 im PGM stehen.

Also zu deiner ersten Frage: er springt nach alle Arbeiten ans Programmende und dann hört das Programm auf, weil im nächsten Satz End PGM steht.

Nächste Frage, da könnte auch jede andere Zahl stehen nur muss die Abfrage ob gleich ist passen, also 5 EQU 5 oder 10 EQU 10, sch.... egal, er soll nur nach LBL 99 springen.

Dann als nächstes das LBL99 ist auch wieder egal, man nimmt halt nen hohen Wert falls man noch mehr Label im Programm schreiben möchte und hier dient das LBL nur als Sprungziel und nicht als Wiederholung, daher auch kein LBL 0.

Du könntest mal versuchen den Vergleich / Sprung mit M30 zu ersetzen, könnte aber sein das dann nur einmal gebohrt wird und dann ist Schluss weil der Rücksprung nicht funzt durch das M30, irgendwo war da nen Haken aber ich weiss im Moment nicht mehr wie und wo der war.

Hoffe dir etwas geholfen zu haben
Tommi

P. S. Karlsblock hat mit seinem letzten Satz auch noch ne Möglichkeit genannt, die ich garnicht bedacht hatte, das es ein gerufenes PGM ist, dann macht das auch noch mehr Sinn ohne M30.
Danke Karlsblock

Der Beitrag wurde von Tommi33 bearbeitet: 01.02.2019, 12:12 Uhr

Hallo
in Satz 20 ist ein Schreibfehler FN 9: IF +0 EQU +0 GOTO LBL 99
FN9:IF Q1 EQU +0 GOTO LBL 99

Wenn Q1 gleich 0 gehe zu LBL 99


Du hast zwei Wiederholungen oben wird Q1 mit 2 belegt


Bis bald 0815

Der Beitrag wurde von 0815fraeser bearbeitet: 02.02.2019, 20:27 Uhr

Wo findest denn "FN9:IF Q1 EQU +0 GOTO LBL 99" in seinem Programm? Ich guck mir die Augen aus aber den Satz find ich nicht.
Karlsblock hat den 1mal als Beispiel genommen, aber auch nur um das zu verdeutlichen was da passiert.

Tommi