Mit Kugelfräser abzeilen, An einer Kontur eine Fase oder Radius an 3 Achs Maschine abzeilen

Hi Leute,

Also wie der Titel beschreibt würde ich gerne ein Programm schreiben oder wissen wie ich eins schreiben kann bei dem die Machine Automatisch den Radius vom Kugelfräser einberechnet, also quasi den exakten Radius zu Fräsen so das immer der Schneidpunkt am Radius einberechnet ist und er nicht zu viel oder zu wenig abfräst, das ganze auch in höhenlinien entlang einer Kontur, also XYZ. Ich habe gesehen das geht mit Vektor Koordinaten, aber laut Buch ist das ein kostenpflichtiges Extra Software Update was ich an meiner Maschine nicht habe. Gibt es eine andere Möglichkeit?

habe eine TNC 530 an der Kunzmann WF4 (3 Achs)

Gruß Julien

Der Beitrag wurde von Der_Dude bearbeitet: 04.01.2024, 11:07 Uhr

Serwus,

im Klartext Portal von Heidenhain gibt es viele nützliche Programme und Beispiele für Parameterprogramme.
Unter anderem eines zum Radiusfräsen

https://www.klartext-portal.de/de_DE/tipps/...kontur-fraesen/

MfG

Hi vielen Dank,

Ich wusste überhaupt nicht das es sowas bei Klartext gibt, gibt es sowas auch zum abzeilen für eine einzelne Fase ohne Kontur mit Kugelfräser?
Hab diesbezüglich nur Programme mit Kontur gefunden.

Der Beitrag wurde von Der_Dude bearbeitet: 04.01.2024, 15:38 Uhr

Also ich hab z.B. eine Rampe vorher mit cycl 231 Regelfläche abgezeilt wenn eine bestimmte Fläche irgendwo angefräst werden musste, würde jetzt nur gerne Wissen wie ich die mit dem Kugelfräser abzeilen kann das die Fläche auch exakt ist, mit einem Normalen Fräser 90° passt zwar die Fläche, würde aber absolut bescheiden aussehen.

Bin mir grad nicht sicher was du mit einzelner Fase/Kontur meinst.
Wenn du eine nicht geschlossene Kontur fahren willst geht das mit diesem Programm genauso. Ist ja mit Cycle 25 Programmiert, da funktionieren offene Konturen auch.

Wenn du eine Fase fräsen möchtest gibt es ein ähnliches Programm halt nur mit Fase

https://www.klartext-portal.de/de_DE/tipps/...kontur-fraesen/

Ja hab eben nochmal geguckt, ich kann die Programme nicht verwenden weil er manche cycl nicht erkennt, im Klartext Portal steht ja auch für welche Steuerungen, und TNC 530 steht da nicht drinnen. In beiden Programmen Satz 55 cycl def 270 Konturzug Daten ist dort ein Error Satz.

Der Beitrag wurde von Der_Dude bearbeitet: 10.01.2024, 13:49 Uhr

Hallo @Der_Dude,

ich weis nicht ob Dir meine Antwort weiterhilft.
Ich erzeuge eine parallele Kontur mit den Abstand des Werzeugschneidenradius.
Das Werkzeug wird Mitte Schneidenradius vermessen.
Das funktioniert sowohl bei linearer als auch bei kreisförmiger Bewegung.
Jeder Punkt ergibt den Konturabstand und Tiefenzustellung und so zeilst Du das ab.
Die Punkte werden in Parametern definiert und im UP angearbeitet.
Bsp.
R3=-9,0 R4=26,25
UP
R3=-9,5 R4=26,75
UP
ect.

VG

Zyklus 270 sollte die 530er kennen, kann auch weggelassen werden, dafür im Konturlabel mit APPR/DEP arbeiten. Also alle 270er raus.
Konturlabel etwa so:

LBL 10 ;Kontur
APPR LT X+10 Y+10 LEN10 RL
L Y+90
CR X+90 Y+90 R+100 DR+
L Y+10
CR X+10 Y+10 R+100 DR-
DEP LT LEN5
LBL 0

Zyklus 25 wie folgt ändern:

CYCL DEF 25 KONTUR-ZUG ~
Q1=-15 ;FRAESTIEFE ~
Q3=+0 ;AUFMASS SEITE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q7=+50 ;SICHERE HOEHE ~
Q10=-5 ;ZUSTELL-TIEFE ~
Q11=+150 ;VORSCHUB TIEFENZ. ~
Q12=+500 ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART ~
Q18=+0 ;VORRAEUM-WERKZEUG ~
Q446=+0.01 ;RESTMATERIAL ~
Q447=+10 ;VERBINDUNGSABSTAND ~
Q448=+2 ;BAHNVERLAENGERUNG

ab Q18 alles weg, dann so:

CYCL DEF 25 KONTUR-ZUG ~
Q1=-15 ;FRAESTIEFE ~
Q3=+0 ;AUFMASS SEITE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q7=+50 ;SICHERE HOEHE ~
Q10=-5 ;ZUSTELL-TIEFE ~
Q11=+150 ;VORSCHUB TIEFENZ. ~
Q12=+500 ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART ~

Natürlich die Parameter jeweils, wie im Originalprogramm, für jeden 25er übernehmen.
Das dann mit allen 25ern und es sollte laufen.

Gruß Jens

Hi danke nochmal an alle für die Antworten, ich hatte mir noch schnell vorher ein Programme selbst geschrieben bei dem ich die Schräge bzw. Fase mit dem Kugelfräser abzeile und auch bestimmen kann in welchem Winkel der Schnitt erfolgen soll. Bin nicht sehr gut im erklären, ich hab die Texte so geschrieben als würde ich versuchen einem Kind das zu erklären mit der Taktik fahre ich immer ganz gut

Beispielprogramm für die abgezeilte Schräge.

0 BEGIN PGM kglfr abzeilen MM
1 BLK FORM 0.1 Z X-38 Y-47 Z-55
2 BLK FORM 0.2 X+0 Y+0 Z+0
3 L
4 L
5 * - T901 Kugelfraeser D10
6 TOOL CALL 901 Z S3000 F1500
7 L
8 * - Alle Angaben werden so eingegeben als wuerde die Schraege oder Fase vor~
einem in Y+ sein.
9 * - Drehen und versetzen kann man die Schraege oder Fase mit der~
NP-Verschiebung und Winkelangaben
10 ;Parametereingabe
11 FN 0: Q1 =+5 ;Fraeserradius
12 FN 0: Q2 =+90 ;Schnittwinkel im Durchmesser des Fraesers einstellen um~
Schraege sauber abzuzeilen (Beispiel: 30 Grad hier fuer den Durchesser~
des Fraesers eintippen auf den Radius gesehen sind es dann 15 Grad)
13 FN 0: Q3 =+0 ;Laenge der Schraege Nullpunkt
14 FN 0: Q6 =+47 ;Laenge der Schraege Koordinate X+
15 FN 0: Q7 =+0 ;Breite der Schraege Nullpunkt
16 FN 0: Q4 =+2 ; Breite der Schraege Y+
17 FN 0: Q18 =+7 ;Hoehe der Schraege Z oben rechts
18 FN 0: Q5 =+5 ;Hoehe der Schraege Z Koordinate unten rechts
19 FN 0: Q8 =+5 ;Hoehe der Schraege Z unten links
20 FN 0: Q17 =+7 ;Hoehe der Schraege Z oben links
21 FN 0: Q16 =+0 ;Winkel zum bestimmen der Schraegrichtung
22 L ;Parametereingabe Ende
23 L
24 L
25 L ;Berechnungen
26 Q9 = 2 * Q1 * SIN ( Q2 / 2 )
27 Q10 = Q9 / 2 * TAN ( Q2 / 4 )
28 Q11 = ( Q1 * 2 - Q9 ) / 2
29 Q12 = Q4 + Q1 - Q11
30 Q13 = Q5 - Q10
31 Q14 = Q7 + Q1 - Q11
32 Q15 = Q8 - Q10
33 Q19 = Q17 - Q10
34 Q20 = Q18 - Q10
35 L ;Berechungen Ende
36 L
37 L
38 L Z+150 R0 FMAX M13
39 L
40 * - NP-Verschiebung je nachdem wohin die Schraege soll
41 CYCL DEF 7.0 NULLPUNKT
42 CYCL DEF 7.1 X-2
43 CYCL DEF 7.2 Y-47
44 CYCL DEF 7.3 Z-7
45 * - NP-Eingabe Ende
46 L
47 CYCL DEF 10.0 DREHUNG
48 CYCL DEF 10.1 ROT+Q16
49 L
50 L
51 L X+Q12 Y+Q6 Z+30 R0 FMAX
52 CYCL DEF 231 REGELFLAECHE ~
Q225=+Q12 ;STARTPUNKT 1. ACHSE ~
Q226=+Q6 ;STARTPUNKT 2. ACHSE ~
Q227=+Q13 ;STARTPUNKT 3. ACHSE ~
Q228=+Q12 ;2. PUNKT 1. ACHSE ~
Q229=+Q3 ;2. PUNKT 2. ACHSE ~
Q230=+Q15 ;2. PUNKT 3. ACHSE ~
Q231=+Q14 ;3. PUNKT 1. ACHSE ~
Q232=+Q3 ;3. PUNKT 2. ACHSE ~
Q233=+Q19 ;3. PUNKT 3. ACHSE ~
Q234=+Q14 ;4. PUNKT 1. ACHSE ~
Q235=+Q6 ;4. PUNKT 2. ACHSE ~
Q236=+Q20 ;4. PUNKT 3. ACHSE ~
Q240=+80 ;ANZAHL SCHNITTE ~
Q207= AUTO ;VORSCHUB FRAESEN
53 CYCL CALL
54 L
55 L
56 CYCL DEF 7.0 NULLPUNKT
57 CYCL DEF 7.1 X+0
58 CYCL DEF 7.2 Y+0
59 CYCL DEF 7.3 Z+0
60 CYCL DEF 10.0 DREHUNG
61 CYCL DEF 10.1 ROT+0
62 L
63 L Z+150 R0 FMAX M9 M5
64 L X-1 Y-1 Z+400 R0 FMAX M91
65 END PGM kglfr abzeilen MM

Der Beitrag wurde von Der_Dude bearbeitet: 19.01.2024, 08:44 Uhr