Niedrigsten Punkt finden

Hallo Forum !

Ich habe mir zum Planfräsen ein Tastprogramm gemacht, bei dem der niedrigste Punkt gemessen werden soll.
In der Mitte des Teiles soll in Z angetastet werden und der Wert auf Z1 gesetzt werden. Dann sollen alle 4 Eckpunkte
gemessen werden und jeweils, fall der gemessene Wert kleiner 1mm ist nochmal in Z antasten und den Wert wieder auf 1mm
aktualisieren. Aber jedesmal wenn die Bedingung erfüllt ist, und das LBL 1 abgearbeitet wird, wird danach das Programm einfach beendet.
Wenn ein LBL mit LBL0 beendet wird, müßte er doch an die Stelle zurückspringen an der das LBL aufgerufen wurde ?
Ich steh voll auf dem Schlauch....
Ich hoffe mir kann jemand weiterhelfen.

0 BEGIN PGM n MM
1 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+1 ;BEZUGSPUNKT-NUMMER
2 TOOL CALL 99 Z S20 ;Messtaster
3 TCH PROBE 417 BZPKT TS.-ACHSE ~
Q263=+0 ;1. PUNKT 1. ACHSE ~
Q264=+0 ;1. PUNKT 2. ACHSE ~
Q294=+1 ;1. PUNKT 3. ACHSE ~
Q320=+15 ;SICHERHEITS-ABST. ~
Q260=+50 ;SICHERE HOEHE ~
Q305=+1 ;NR. IN TABELLE ~
Q333=+1 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE
4 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+1 ;BEZUGSPUNKT-NUMMER
5 TCH PROBE 427 MESSEN KOORDINATE ~
Q263=-370 ;1. PUNKT 1. ACHSE ~
Q264=+300 ;1. PUNKT 2. ACHSE ~
Q261=+1 ;MESSHOEHE ~
Q320=+15 ;SICHERHEITS-ABST. ~
Q272=+3 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q260=+50 ;SICHERE HOEHE ~
Q281=+0 ;MESSPROTOKOLL ~
Q288=+0 ;GROESSTMASS ~
Q289=+0 ;KLEINSTMASS ~
Q309=+0 ;PGM-STOP BEI FEHLER ~
Q330=+0 ;WERKZEUG
6 FN 12: IF +Q160 LT +1 GOTO LBL 1
7 TCH PROBE 427 MESSEN KOORDINATE ~
Q263=-370 ;1. PUNKT 1. ACHSE ~
Q264=+300 ;1. PUNKT 2. ACHSE ~
Q261=+1 ;MESSHOEHE ~
Q320=+15 ;SICHERHEITS-ABST. ~
Q272=+3 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q260=+50 ;SICHERE HOEHE ~
Q281=+0 ;MESSPROTOKOLL ~
Q288=+0 ;GROESSTMASS ~
Q289=+0 ;KLEINSTMASS ~
Q309=+0 ;PGM-STOP BEI FEHLER ~
Q330=+0 ;WERKZEUG
8 FN 12: IF +Q160 LT +1 GOTO LBL 1
9 TCH PROBE 427 MESSEN KOORDINATE ~
Q263=-370 ;1. PUNKT 1. ACHSE ~
Q264=-300 ;1. PUNKT 2. ACHSE ~
Q261=+1 ;MESSHOEHE ~
Q320=+15 ;SICHERHEITS-ABST. ~
Q272=+3 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q260=+50 ;SICHERE HOEHE ~
Q281=+0 ;MESSPROTOKOLL ~
Q288=+0 ;GROESSTMASS ~
Q289=+0 ;KLEINSTMASS ~
Q309=+0 ;PGM-STOP BEI FEHLER ~
Q330=+0 ;WERKZEUG
10 FN 12: IF +Q160 LT +1 GOTO LBL 1
11 TCH PROBE 427 MESSEN KOORDINATE ~
Q263=+370 ;1. PUNKT 1. ACHSE ~
Q264=+300 ;1. PUNKT 2. ACHSE ~
Q261=+1 ;MESSHOEHE ~
Q320=+15 ;SICHERHEITS-ABST. ~
Q272=+3 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q260=+50 ;SICHERE HOEHE ~
Q281=+0 ;MESSPROTOKOLL ~
Q288=+0 ;GROESSTMASS ~
Q289=+0 ;KLEINSTMASS ~
Q309=+0 ;PGM-STOP BEI FEHLER ~
Q330=+0 ;WERKZEUG
12 FN 12: IF +Q160 LT +1 GOTO LBL 1
13 L Z-10 R0 FMAX M91
14 L X-50 Y-10 R0 FMAX M91
15 M30
16 LBL 1
17 FN 18: SYSREAD Q66 = ID270 NR1 IDX1.0 ;Lesen aktuelle Position X-Achse
18 FN 18: SYSREAD Q67 = ID270 NR1 IDX2.0 ;Lesen aktuelle Position Y-Achse
19 TCH PROBE 417 BZPKT TS.-ACHSE ~
Q263=+Q66 ;1. PUNKT 1. ACHSE ~
Q264=+Q67 ;1. PUNKT 2. ACHSE ~
Q294=+1 ;1. PUNKT 3. ACHSE ~
Q320=+15 ;SICHERHEITS-ABST. ~
Q260=+50 ;SICHERE HOEHE ~
Q305=+1 ;NR. IN TABELLE ~
Q333=+1 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE
20 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+1 ;BEZUGSPUNKT-NUMMER
21 LBL 0
22 END PGM n MM

Gruß
Sven

Der Beitrag wurde von GreenVeltlins77 bearbeitet: 04.04.2013, 10:31 Uhr

Nur CALL LBL .. springt bei LBL 0 zurück.
IF GOTO und CALL LBL .. REP nicht.

Schreib das Messen doch einfach mit ins Label:

..
Q66 = +370 ; X
Q67 = +300 ; Y
CALL LBL 1
Q66 = +370 ; X
Q67 = -300 ; Y
CALL LBL 1
..
M30
LBL 1
TCH PROBE 427 MESSEN KOORDINATE ~
Q263=Q66 ;1. PUNKT 1. ACHSE ~
Q264=Q67 ;1. PUNKT 2. ACHSE ~
Q261=+1 ;MESSHOEHE ~
Q320=+15 ;SICHERHEITS-ABST. ~
Q272=+3 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q260=+50 ;SICHERE HOEHE ~
Q281=+0 ;MESSPROTOKOLL ~
Q288=+0 ;GROESSTMASS ~
Q289=+0 ;KLEINSTMASS ~
Q309=+0 ;PGM-STOP BEI FEHLER ~
Q330=+0 ;WERKZEUG
FN 12: IF +Q160 GT +1 GOTO LBL 2
TCH PROBE 417 BZPKT TS.-ACHSE ~
Q263=+Q66 ;1. PUNKT 1. ACHSE ~
Q264=+Q67 ;1. PUNKT 2. ACHSE ~
Q294=+1 ;1. PUNKT 3. ACHSE ~
Q320=+15 ;SICHERHEITS-ABST. ~
Q260=+50 ;SICHERE HOEHE ~
Q305=+1 ;NR. IN TABELLE ~
Q333=+1 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE
20 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+1 ;BEZUGSPUNKT-NUMMER
LBL 2
LBL 0
END PGM n MM

Gruß
cgTNC

Der Beitrag wurde von cgTNC bearbeitet: 04.04.2013, 11:01 Uhr

Hallo cgTNC !

Das erklärt so manches....

Ich hab's so wie von Dir vorgeschlagen umgebaut.
Hier die funktionsfähige parametrische Version:

0 BEGIN PGM Antasten-Planfraesen MM
1 * - Info
2 ;Ursprungspreset #14 nullen in XY = Kante rechts oben
3 ;Presetnummer 14 = Auflageflaeche Tisch
4 ;Programm mittelt Teil aus und tastet niedrigsten Punkt an
5 ;Teil auf Tisch gespannt
6 ;
7 * - Parameter
8 ;**********Parameter wichtig!!***************
9 ;
10 FN 0: Q30 =+1 ;Presetnummer
11 FN 0: Q31 =+788 ;Teillaenge X
12 FN 0: Q32 =+643 ;Teilbreite Y
13 FN 0: Q33 =+172 ;Teilhoehe Z
14 FN 0: Q34 =+1 ;Aufmass Z
15 ;
16 ;******Parameter nicht so wichtig!!**********
17 FN 0: Q37 =+20 ;Tastmass von aussen
18 FN 0: Q38 =+15 ;Sicherheitsabstand Zyklen
19 FN 0: Q39 =+50 ;Sichere Hoehe Zyklen
20 FN 0: Q40 =+14 ;Ursprungspreset
21 FN 0: Q41 =+6 ;Tasttiefe
22 ;
23 * - Berechnung
24 ;**********Berechnung************************
25 ;
26 FN 4: Q50 =+Q31 DIV +2 ;Haelfte X
27 FN 4: Q51 =+Q32 DIV +2 ;Haelfte Y
28 FN 2: Q52 =+Q50 - +Q37 ;Tastpositionen X
29 FN 2: Q53 =+Q51 - +Q37 ;Tastpositionen Y
30 FN 2: Q54 =+Q33 - +Q41 ;Tasthoehe Z
31 FN 1: Q55 =+Q33 + +Q39 ;Sichere Hoehe
32 FN 17: SYSWRITE ID 503 NRQ30 IDX3.0 =-Q33 ;Schreiben Preset Q30 Z-Achse mit~
Verrechnung
33 FN 17: SYSWRITE ID 503 NRQ30 IDX4.0 =+0 ;Schreiben Preset Q30 A-Achse
34 FN 17: SYSWRITE ID 503 NRQ30 IDX5.0 =+0 ;Schreiben Preset Q30 B-Achse
35 FN 17: SYSWRITE ID 503 NRQ30 IDX6.0 =+0 ;Schreiben Preset Q30 C-Achse
36 FN 17: SYSWRITE ID 504 NRQ30 =+0 ;Preset Q30 Grunddrehung Rot auf 0 setzen
37 FN 17: SYSWRITE ID 210 NR1 =+0 ;Manuelle Grunddrehung auf 0 setzen
38 ;
39 * - Programmstart
40 ;********Programmstart***********************
41 ;
42 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+Q40 ;BEZUGSPUNKT-NUMMER
43 L Z-10 R0 FMAX M91
44 L X-50 Y-10 R0 FMAX M91
45 PLANE RESET STAY
46 L B+Q121 R0 FMAX
47 TOOL CALL 99 S20 ;Messtaster
48 TCH PROBE 411 BZPKT RECHTECK AUS. ~
Q321=-Q50 ;MITTE 1. ACHSE ~
Q322=-Q51 ;MITTE 2. ACHSE ~
Q323=+Q31 ;1. SEITEN-LAENGE ~
Q324=+Q32 ;2. SEITEN-LAENGE ~
Q261=+Q54 ;MESSHOEHE ~
Q320=+Q38 ;SICHERHEITS-ABST. ~
Q260=+Q55 ;SICHERE HOEHE ~
Q301=+1 ;FAHREN AUF S. HOEHE ~
Q305=+Q30 ;NR. IN TABELLE ~
Q331=+0 ;BEZUGSPUNKT ~
Q332=+0 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE ~
Q381=+1 ;ANTASTEN TS-ACHSE ~
Q382=-Q50 ;1. KO. FUER TS-ACHSE ~
Q383=-Q51 ;2. KO. FUER TS-ACHSE ~
Q384=+Q33 ;3. KO. FUER TS-ACHSE ~
Q333=+Q34 ;BEZUGSPUNKT
49 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+Q30 ;BEZUGSPUNKT-NUMMER
50 FN 0: Q60 =+Q52
51 FN 0: Q61 =+Q53
52 CALL LBL 1
53 FN 0: Q60 =-Q52
54 FN 0: Q61 =+Q53
55 CALL LBL 1
56 FN 0: Q60 =-Q52
57 FN 0: Q61 =-Q53
58 CALL LBL 1
59 FN 0: Q60 =+Q52
60 FN 0: Q61 =-Q53
61 CALL LBL 1
62 L Z-10 R0 FMAX M91
63 L X-50 Y-10 R0 FMAX M91
64 M30
65 * - LBL 1 - Punkt in Z messen
66 LBL 1
67 TCH PROBE 427 MESSEN KOORDINATE ~
Q263=+Q60 ;1. PUNKT 1. ACHSE ~
Q264=+Q61 ;1. PUNKT 2. ACHSE ~
Q261=+Q34 ;MESSHOEHE ~
Q320=+Q38 ;SICHERHEITS-ABST. ~
Q272=+3 ;MESSACHSE ~
Q267=-1 ;VERFAHRRICHTUNG ~
Q260=+Q39 ;SICHERE HOEHE ~
Q281=+0 ;MESSPROTOKOLL ~
Q288=+0 ;GROESSTMASS ~
Q289=+0 ;KLEINSTMASS ~
Q309=+0 ;PGM-STOP BEI FEHLER ~
Q330=+0 ;WERKZEUG
68 FN 11: IF +Q160 GT +Q34 GOTO LBL 2
69 TCH PROBE 417 BZPKT TS.-ACHSE ~
Q263=+Q60 ;1. PUNKT 1. ACHSE ~
Q264=+Q61 ;1. PUNKT 2. ACHSE ~
Q294=+Q34 ;1. PUNKT 3. ACHSE ~
Q320=+Q38 ;SICHERHEITS-ABST. ~
Q260=+Q39 ;SICHERE HOEHE ~
Q305=+Q30 ;NR. IN TABELLE ~
Q333=+Q34 ;BEZUGSPUNKT ~
Q303=+1 ;MESSWERT-UEBERGABE
70 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
Q339=+Q30 ;BEZUGSPUNKT-NUMMER
71 LBL 2
72 LBL 0
73 END PGM Antasten-Planfraesen MM

Vielen Dank !!

Gruß
Sven