QUOTE
Hat jemand noch ein einfaches Programm...vielleicht sogar unter DOS wo man die Masse berechnen kann?
Sie haben DOS, dann haben Sie auch noch GWBASIC oder QBASIC. Einfach dieses Programm mit STRG-C markieren, auf Ihrem Rechner in den Editor oder Wordpad einfügen, als "Lochkr.bas" spreichern. Wenn Ihnen Wordpad noch ein .txt dranhängt, dann das wieder mit Umbenennen wegmachen.
Das Programm starten Sie ganz einfach mit GWBASIC Lochkr , man kann es auch mit STRG-C abbrechen.
Das Programm fragt anfangs ein paar Werte ab, beim Winkelschritt müssen Sie was eingeben, ansonsten können Sie auch einfach mit Return drübergehen, der Wert ist dann Null.
Dann kriegen Sie eine Tabelle der Werte, immer 10 Zeilen. Zudem speichert Ihnen das Programm noch eine Tabelle aller Zahlen ab, die finden Sie als "Zahlen.txt" im aktuellen Verzeichnis, können Sie mit dem DOS-Editor aufmachen oder auch nach Excel holen und Ausdrucken.
Wenn Sie GWBASIC oder QBASIC nicht haben sollten, bitte Bescheid sagen.
10 CLS
15 XM = 0: YM = 0 : RM = 0 : SM = 0
20 INPUT "X-Koordinate Mittelpunkt";XM
30 INPUT "Y-Koordinate Mittelpunkt";YM
40 INPUT "Radius des Lochkreises ";RM
50 INPUT "Startwinkel in Grad zur Horizontalen";SM
60 INPUT "Winkelschritt in Grad"; WM
100 PRINT
120 PI = 3.14159
130 IF WM<.01 THEN STOP
140 N = INT (360/WM)
150 ZEILE = 0
160 PRINT N
170 OPEN "Zahlen.txt" FOR OUTPUT AS#1
200 FOR I = 0 TO N
210 W = (SM + I*WM) * PI/180
220 X = XM + RM*COS(W)
230 Y = YM + RM*SIN(W)
240 GOSUB 500 : GOSUB 600
250 ZEILE = ZEILE+1
260 IF ZEILE > 10 THEN INPUT"Weiter mit Enter", X$:CLS:ZEILE = 0
270 NEXT
280 CLOSE 1
290 END
500 PRINT USING "####";I;
510 PRINT USING "####.####";SM+I*WM;:PRINT " Grad ";
520 PRINT " x = "; USING "####.####";X;
530 PRINT " y = "; USING "####.####";Y
540 RETURN
600 PRINT#1, USING "####";I;
610 PRINT#1,USING "####.####";SM+I*WM;:PRINT#1, " Grad ";
620 PRINT#1," X = "; USING "####.####";X;
630 PRINT#1," y = "; USING "####.####";Y
640 RETURN